blob: a6a610dcd8d7a5e8b42d070e7e3d4c440944a863 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
TEMPLATE = app
SOURCES += main.cpp
QT += core gui testlib
CONFIG += app_bundle
TARGET = tst_manual_ios_assets
# Custom Info.plist
ios {
QMAKE_INFO_PLIST = Info.ios.qmake.plist
}
# Custom resources
textFiles.files = $$files(*.txt)
# On iOS no 'Resources' prefix is needed because iOS app bundles are shallow,
# so the final location of the text file will be
# tst_manual_ios_assets.app/textFiles/foo.txt
# Specifying a Resources prefix actually causes code signing error for some reason.
# On macOS the location will be
# tst_manual_ios_assets.app/Contents/Resources/textFiles/foo.txt
ios {
textFiles.path = textFiles
}
macos {
textFiles.path = Contents/Resources/textFiles
}
QMAKE_BUNDLE_DATA += textFiles
# App icons
ios {
ios_icon.files = $$files($$PWD/appicon/AppIcon*.png)
QMAKE_BUNDLE_DATA += ios_icon
}
# Asset catalog with images
ios {
# The asset catalog needs to have an empty AppIcon.appiconset, otherwise Xcode refuses
# to compile the asset catalog.
QMAKE_ASSET_CATALOGS += Assets.xcassets
SOURCES += utils.mm
LIBS += -framework UIKit
}
# Set custom launch screen
ios {
# Underneath, this uses QMAKE_BUNDLE_DATA, prevents the default launch screen from being set
# and bundles the custom one.
QMAKE_IOS_LAUNCH_SCREEN = $$PWD/CustomLaunchScreen.storyboard
}
|
