blob: d94eec1bcb37b7c101b5d56ae6e089e3cd00fafa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
include($$OUT_PWD/../../src/charts/qtcharts-config.pri)
QT_FOR_CONFIG += charts
TEMPLATE = subdirs
qtConfig(charts-area-chart) {
SUBDIRS += areachart
}
qtConfig(charts-line-chart) {
SUBDIRS += \
callout \
chartinteractions \
customchart \
linechart \
lineandbar \
legendmarkers \
logvalueaxis \
modeldata \
zoomlinechart
}
qtConfig(charts-spline-chart) {
SUBDIRS += \
dynamicspline \
multiaxis \
splinechart
qtConfig(charts-area-chart) {
SUBDIRS += \
chartthemes \
polarchart
}
}
qtConfig(charts-bar-chart) {
SUBDIRS += \
barchart \
barmodelmapper \
horizontalbarchart \
horizontalpercentbarchart \
horizontalstackedbarchart \
stackedbarchart \
stackedbarchartdrilldown \
percentbarchart \
legend \
temperaturerecords
}
qtConfig(charts-pie-chart) {
SUBDIRS += \
donutchart \
donutbreakdown \
nesteddonuts \
piechart \
piechartcustomization \
piechartdrilldown
qtHaveModule(quick): SUBDIRS += qmlpiechart
}
qtConfig(charts-boxplot-chart) {
SUBDIRS += boxplotchart
qtHaveModule(quick): SUBDIRS += qmlboxplot
}
qtConfig(charts-candlestick-chart) {
SUBDIRS += candlestickchart
qtHaveModule(quick): SUBDIRS += qmlcandlestick
}
qtConfig(charts-scatter-chart) {
SUBDIRS += \
scatterchart \
scatterinteractions
}
qtHaveModule(quick) {
SUBDIRS += \
qmlaxes \
qmlchart \
qmlcustomizations \
qmlcustomlegend \
qmlf1legends \
qmloscilloscope \
qmlpolarchart \
qmlweather
}
qtHaveModule(multimedia) {
SUBDIRS += audio
} else {
message("QtMultimedia library not available. Some examples are disabled.")
}
contains(QT_CONFIG, opengl) {
SUBDIRS += openglseries
} else {
message("OpenGL not available. Some examples are disabled.")
}
!contains(QT_COORD_TYPE, float): {
SUBDIRS += \
datetimeaxis
}
|