blob: b41c259dbfabb66ab88bf0fdb3de9a77bf602acd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
// Copyright (C) 2013 BlackBerry Limited. All rights reserved.
// Copyright (C) 2023 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
pragma ComponentBehavior: Bound
import QtCore
import QtQuick
Rectangle {
id: devicesPage
property bool deviceState: Device.state
signal showServices
width: 300
height: 600
function toggleDiscovery() {
if (!Device.state) {
Device.startDeviceDiscovery()
// if startDeviceDiscovery() failed Device.state is not set
if (Device.state) {
info.dialogText = "Searching..."
info.visible = true
}
} else {
Device.stopDeviceDiscovery()
}
}
onDeviceStateChanged: {
if (!Device.state)
info.visible = false
}
Header {
id: header
anchors.top: parent.top
headerText: {
if (Device.state)
return "Discovering"
if (Device.devicesList.length > 0)
return "Select a device"
return "Start Discovery"
}
}
Dialog {
id: info
anchors.centerIn: parent
visible: false
}
ListView {
id: theListView
width: parent.width
clip: true
anchors.top: header.bottom
anchors.bottom: connectToggle.top
model: Device.devicesList
delegate: Rectangle {
required property var modelData
id: box
height: 100
width: theListView.width
color: "lightsteelblue"
border.width: 2
border.color: "black"
radius: 5
MouseArea {
anchors.fill: parent
onClicked: {
Device.scanServices(box.modelData.deviceAddress)
showServices()
}
}
Label {
id: deviceName
textContent: box.modelData.deviceName
anchors.top: parent.top
anchors.topMargin: 5
}
Label {
id: deviceAddress
textContent: box.modelData.deviceAddress
font.pointSize: deviceName.font.pointSize * 0.7
anchors.bottom: box.bottom
anchors.bottomMargin: 5
}
}
}
Menu {
id: connectToggle
menuWidth: parent.width
anchors.bottom: menu.top
menuText: {
visible = Device.devicesList.length > 0
if (Device.useRandomAddress)
return "Address type: Random"
else
return "Address type: Public"
}
onButtonClick: Device.useRandomAddress = !Device.useRandomAddress
}
//! [permission-object]
BluetoothPermission {
id: permission
communicationModes: BluetoothPermission.Access
onStatusChanged: {
if (permission.status === Qt.PermissionStatus.Denied)
Device.update = "Bluetooth permission required"
else if (permission.status === Qt.PermissionStatus.Granted)
devicesPage.toggleDiscovery()
}
}
//! [permission-object]
Menu {
id: menu
anchors.bottom: parent.bottom
menuWidth: parent.width
menuHeight: (parent.height / 6)
menuText: Device.update
//! [permission-request]
onButtonClick: {
if (permission.status === Qt.PermissionStatus.Undetermined)
permission.request()
else if (permission.status === Qt.PermissionStatus.Granted)
devicesPage.toggleDiscovery()
}
//! [permission-request]
}
}
|
