blob: b15f8bacdb822a72c1b85dd610a1248003fd402f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
|
/****************************************************************************
**
** Copyright (C) 2016 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Qt Data Visualization module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:GPL$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick
import QtQuick.Layouts
import QtQuick.Controls
import QtDataVisualization 1.2
import "."
Item {
id: mainview
width: 1280
height: 720
property real fontSize: 12
property bool portraitMode: width < height
Item {
id: surfaceView
width: mainview.width - settings.width
height: mainview.height
anchors.right: mainview.right;
//! [0]
ColorGradient {
id: layerOneGradient
ColorGradientStop { position: 0.0; color: "black" }
ColorGradientStop { position: 0.31; color: "tan" }
ColorGradientStop { position: 0.32; color: "green" }
ColorGradientStop { position: 0.40; color: "darkslategray" }
ColorGradientStop { position: 1.0; color: "white" }
}
ColorGradient {
id: layerTwoGradient
ColorGradientStop { position: 0.315; color: "blue" }
ColorGradientStop { position: 0.33; color: "white" }
}
ColorGradient {
id: layerThreeGradient
ColorGradientStop { position: 0.0; color: "red" }
ColorGradientStop { position: 0.15; color: "black" }
}
//! [0]
Surface3D {
id: surfaceLayers
width: surfaceView.width
height: surfaceView.height
theme: Theme3D {
type: Theme3D.ThemeEbony
font.pointSize: 35
colorStyle: Theme3D.ColorStyleRangeGradient
}
shadowQuality: AbstractGraph3D.ShadowQualityNone
selectionMode: AbstractGraph3D.SelectionRow | AbstractGraph3D.SelectionSlice
scene.activeCamera.cameraPreset: Camera3D.CameraPresetIsometricLeft
axisY.min: 20
axisY.max: 200
axisX.segmentCount: 5
axisX.subSegmentCount: 2
axisX.labelFormat: "%i"
axisZ.segmentCount: 5
axisZ.subSegmentCount: 2
axisZ.labelFormat: "%i"
axisY.segmentCount: 5
axisY.subSegmentCount: 2
axisY.labelFormat: "%i"
//! [1]
//! [2]
Surface3DSeries {
id: layerOneSeries
baseGradient: layerOneGradient
//! [2]
HeightMapSurfaceDataProxy {
heightMapFile: ":/heightmaps/layer_1.png"
}
flatShadingEnabled: false
drawMode: Surface3DSeries.DrawSurface
//! [4]
visible: layerOneToggle.checked // bind to checkbox state
//! [4]
}
Surface3DSeries {
id: layerTwoSeries
baseGradient: layerTwoGradient
HeightMapSurfaceDataProxy {
heightMapFile: ":/heightmaps/layer_2.png"
}
flatShadingEnabled: false
drawMode: Surface3DSeries.DrawSurface
visible: layerTwoToggle.checked // bind to checkbox state
}
Surface3DSeries {
id: layerThreeSeries
baseGradient: layerThreeGradient
HeightMapSurfaceDataProxy {
heightMapFile: ":/heightmaps/layer_3.png"
}
flatShadingEnabled: false
drawMode: Surface3DSeries.DrawSurface
visible: layerThreeToggle.checked // bind to checkbox state
}
//! [1]
}
}
Flickable {
id: settings
width: buttonLayout.width
contentHeight: buttonLayout.height
height: mainview.height
ColumnLayout {
id: buttonLayout
anchors.top: parent.top
anchors.left: parent.left
spacing: 0
//! [3]
GroupBox {
Layout.fillWidth: true
Column {
spacing: 10
Label {
font.pointSize: fontSize
font.bold: true
text: portraitMode ? "Layer\nSelection" : "Layer Selection"
}
CheckBox {
id: layerOneToggle
checked: true
text: portraitMode ? "Show\nGround\nLayer" : "Show Ground Layer"
}
CheckBox {
id: layerTwoToggle
checked: true
text: portraitMode ? "Show\nSea\nLayer" : "Show Sea Layer"
}
CheckBox {
id: layerThreeToggle
checked: true
text: portraitMode ? "Show\nTectonic\nLayer" : "Show Tectonic Layer"
}
}
}
//! [3]
//! [5]
GroupBox {
Layout.fillWidth: true
Column {
spacing: 10
Label {
font.pointSize: fontSize
font.bold: true
text: portraitMode ? "Layer\nStyle" : "Layer Style"
}
CheckBox {
id: layerOneGrid
text: portraitMode ? "Show\nGround\nas Grid" : "Show Ground as Grid"
onCheckedChanged: {
if (checked)
layerOneSeries.drawMode = Surface3DSeries.DrawWireframe
else
layerOneSeries.drawMode = Surface3DSeries.DrawSurface
}
}
CheckBox {
id: layerTwoGrid
text: portraitMode ? "Show\nSea\nas Grid" : "Show Sea as Grid"
onCheckedChanged: {
if (checked)
layerTwoSeries.drawMode = Surface3DSeries.DrawWireframe
else
layerTwoSeries.drawMode = Surface3DSeries.DrawSurface
}
}
CheckBox {
id: layerThreeGrid
text: portraitMode ? "Show\nTectonic\nas Grid" : "Show Tectonic as Grid"
onCheckedChanged: {
if (checked)
layerThreeSeries.drawMode = Surface3DSeries.DrawWireframe
else
layerThreeSeries.drawMode = Surface3DSeries.DrawSurface
}
}
}
}
//! [5]
//! [6]
Button {
id: sliceButton
text: portraitMode ? "Slice\nAll\nLayers" : "Slice All Layers"
Layout.fillWidth: true
Layout.minimumHeight: 40
onClicked: {
if (surfaceLayers.selectionMode & AbstractGraph3D.SelectionMultiSeries) {
surfaceLayers.selectionMode = AbstractGraph3D.SelectionRow
| AbstractGraph3D.SelectionSlice
text = portraitMode ? "Slice\nAll\nLayers" : "Slice All Layers"
} else {
surfaceLayers.selectionMode = AbstractGraph3D.SelectionRow
| AbstractGraph3D.SelectionSlice
| AbstractGraph3D.SelectionMultiSeries
text = portraitMode ? "Slice\nOne\nLayer" : "Slice One Layer"
}
}
}
//! [6]
Button {
id: shadowButton
Layout.fillWidth: true
Layout.minimumHeight: 40
text: surfaceLayers.shadowsSupported ? (portraitMode ? "Show\nShadows" : "Show Shadows")
: (portraitMode ? "Shadows\nnot\nsupported" : "Shadows not supported")
enabled: surfaceLayers.shadowsSupported
onClicked: {
if (surfaceLayers.shadowQuality === AbstractGraph3D.ShadowQualityNone) {
surfaceLayers.shadowQuality = AbstractGraph3D.ShadowQualityLow
text = portraitMode ? "Hide\nShadows" : "Hide Shadows"
} else {
surfaceLayers.shadowQuality = AbstractGraph3D.ShadowQualityNone
text = portraitMode ? "Show\nShadows" : "Show Shadows"
}
}
}
Button {
id: renderModeButton
text: portraitMode ? "Switch\nRender\nMode" : "Switch Render Mode"
Layout.fillWidth: true
Layout.minimumHeight: 40
onClicked: {
var modeText = "Indirect, "
var aaText
if (surfaceLayers.renderingMode === AbstractGraph3D.RenderIndirect &&
surfaceLayers.msaaSamples === 0) {
surfaceLayers.renderingMode = AbstractGraph3D.RenderDirectToBackground
modeText = "BackGround, "
} else if (surfaceLayers.renderingMode === AbstractGraph3D.RenderIndirect &&
surfaceLayers.msaaSamples === 4) {
surfaceLayers.renderingMode = AbstractGraph3D.RenderIndirect
surfaceLayers.msaaSamples = 0
} else if (surfaceLayers.renderingMode === AbstractGraph3D.RenderIndirect &&
surfaceLayers.msaaSamples === 8) {
surfaceLayers.renderingMode = AbstractGraph3D.RenderIndirect
surfaceLayers.msaaSamples = 4
} else {
surfaceLayers.renderingMode = AbstractGraph3D.RenderIndirect
surfaceLayers.msaaSamples = 8
}
if (surfaceLayers.msaaSamples <= 0) {
aaText = "No AA"
} else {
aaText = surfaceLayers.msaaSamples + "xMSAA"
}
renderLabel.text = modeText + aaText
}
}
TextField {
id: renderLabel
font.pointSize: fontSize
Layout.fillWidth: true
Layout.minimumHeight: 40
color: "gray"
enabled: false
horizontalAlignment: TextInput.AlignHCenter
wrapMode: TextField.WrapAtWordBoundaryOrAnywhere
text: "Indirect, " + surfaceLayers.msaaSamples + "xMSAA"
}
}
}
}
|