Remove "2" from Qt Quick Controls directories

Qt Quick Controls 2 was named that way because it was a follow-up to
Qt Quick Controls 1.x. Now that Qt Quick Controls 1 is no longer
supported, we don't need to have "2" in the name. Work on this was
already started for the documentation in
1abdfe5d5a052f2298b7bf657513dfa7e0c66a56.

By doing this renaming a few weeks before feature freeze, it won't
affect the release but still results in as little time possible spent
manually fixing conflicts in cherry-picks from non-LTS releases as a
result of the renaming.

This patch does the following:

- Renames directories.
- Adapts CMakeLists.txt and other files to account for the new paths.

A follow-up patch will handle documentation.

It does not touch library names or other user-facing stuff, as that
will have to be done in Qt 7.

Task-number: QTBUG-95413
Change-Id: I170d8db19033ee71e495ff0c5c1a517a41ed7634
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

1 files changed, 55 insertions, 0 deletions

diff --git a/src/quickcontrols/imagine/BusyIndicator.qml b/src/quickcontrols/imagine/BusyIndicator.qml
new file mode 100644
index 0000000000..6dc40dc4be
--- /dev/null
+++ b/src/quickcontrols/imagine/BusyIndicator.qml
@@ -0,0 +1,55 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.BusyIndicator {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    contentItem: AnimatedImage {
+        opacity: control.running ? 1 : 0
+        playing: control.running || opacity > 0
+        visible: control.running || opacity > 0
+        Behavior on opacity { OpacityAnimator { duration: 250 } }
+
+        source: Imagine.url + "busyindicator-animation"
+        AnimatedImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"running": control.running},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+    }
+
+    background: NinePatchImage {
+        source: Imagine.url + "busyindicator-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"running": control.running},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+    }
+}