Remove "2" from Qt Quick Controls directories

Qt Quick Controls 2 was named that way because it was a follow-up to
Qt Quick Controls 1.x. Now that Qt Quick Controls 1 is no longer
supported, we don't need to have "2" in the name. Work on this was
already started for the documentation in
1abdfe5d5a052f2298b7bf657513dfa7e0c66a56.

By doing this renaming a few weeks before feature freeze, it won't
affect the release but still results in as little time possible spent
manually fixing conflicts in cherry-picks from non-LTS releases as a
result of the renaming.

This patch does the following:

- Renames directories.
- Adapts CMakeLists.txt and other files to account for the new paths.

A follow-up patch will handle documentation.

It does not touch library names or other user-facing stuff, as that
will have to be done in Qt 7.

Task-number: QTBUG-95413
Change-Id: I170d8db19033ee71e495ff0c5c1a517a41ed7634
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

1 files changed, 101 insertions, 0 deletions

diff --git a/src/quickcontrols/imagine/RangeSlider.qml b/src/quickcontrols/imagine/RangeSlider.qml
new file mode 100644
index 0000000000..e0559e65b3
--- /dev/null
+++ b/src/quickcontrols/imagine/RangeSlider.qml
@@ -0,0 +1,101 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.RangeSlider {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            first.implicitHandleWidth + leftPadding + rightPadding,
+                            second.implicitHandleWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             first.implicitHandleHeight + topPadding + bottomPadding,
+                             second.implicitHandleHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    first.handle: Image {
+        x: control.leftPadding + (control.horizontal ? control.first.visualPosition * (control.availableWidth - width) : (control.availableWidth - width) / 2)
+        y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : control.first.visualPosition * (control.availableHeight - height))
+
+        source: control.Imagine.url + "rangeslider-handle"
+        ImageSelector on source {
+            states: [
+                {"first": true},
+                {"vertical": control.vertical},
+                {"horizontal": control.horizontal},
+                {"disabled": !control.enabled},
+                {"pressed": control.first.pressed},
+                {"focused": control.first.handle.activeFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.first.hovered}
+            ]
+        }
+    }
+
+    second.handle: Image {
+        x: control.leftPadding + (control.horizontal ? control.second.visualPosition * (control.availableWidth - width) : (control.availableWidth - width) / 2)
+        y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : control.second.visualPosition * (control.availableHeight - height))
+
+        source: control.Imagine.url + "rangeslider-handle"
+        ImageSelector on source {
+            states: [
+                {"second": true},
+                {"vertical": control.vertical},
+                {"horizontal": control.horizontal},
+                {"disabled": !control.enabled},
+                {"pressed": control.second.pressed},
+                {"focused": control.second.handle.activeFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.second.hovered}
+            ]
+        }
+    }
+
+    background: NinePatchImage {
+        scale: control.horizontal && control.mirrored ? -1 : 1
+
+        source: control.Imagine.url + "rangeslider-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"vertical": control.vertical},
+                {"horizontal": control.horizontal},
+                {"disabled": !control.enabled},
+                {"focused": control.visualFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+
+        NinePatchImage {
+            x: control.horizontal ? control.first.handle.width / 2 + control.first.position * (parent.width - control.first.handle.width) : (parent.width - width) / 2
+            y: control.horizontal ? (parent.height - height) / 2 : control.first.handle.height / 2 + control.second.visualPosition * (parent.height - control.first.handle.height)
+            width: control.horizontal ? control.second.position * (parent.width - control.first.handle.width) - control.first.position * (parent.width - control.first.handle.width) : parent.width
+            height: control.vertical ? control.second.position * (parent.height - control.first.handle.height) - control.first.position * (parent.height - control.first.handle.height): parent.height
+
+            source: control.Imagine.url + "rangeslider-progress"
+            NinePatchImageSelector on source {
+                states: [
+                    {"vertical": control.vertical},
+                    {"horizontal": control.horizontal},
+                    {"disabled": !control.enabled},
+                    {"focused": control.visualFocus},
+                    {"mirrored": control.mirrored},
+                    {"hovered": control.enabled && control.hovered}
+                ]
+            }
+        }
+    }
+}