1 files changed, 57 insertions, 0 deletions
diff --git a/examples/core/permissions/CMakeLists.txt b/examples/core/permissions/CMakeLists.txt
new file mode 100644
index 0000000000..d09acc335a
--- /dev/null
+++ b/examples/core/permissions/CMakeLists.txt
@@ -0,0 +1,57 @@
+# Copyright (C) 2023 The Qt Company Ltd.
+# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+cmake_minimum_required(VERSION 3.16)
+project(permissions LANGUAGES CXX)
+
+set(CMAKE_AUTOMOC ON)
+
+find_package(Qt6 REQUIRED COMPONENTS Core Gui Quick QuickControls2)
+qt_standard_project_setup(REQUIRES 6.6)
+
+qt_add_executable(permissions
+    main.cpp
+)
+
+qt_add_qml_module(permissions
+    URI PermissionsExample
+    QML_FILES
+        "Main.qml"
+)
+
+target_link_libraries(permissions PUBLIC
+    Qt::Core
+    Qt::CorePrivate
+    Qt::Gui
+    Qt::Quick
+    Qt::QuickControls2
+)
+
+if(UNIX AND NOT APPLE AND CMAKE_CROSSCOMPILING)
+    find_package(Qt6 REQUIRED COMPONENTS QuickTemplates2)
+
+    # Work around QTBUG-86533
+    target_link_libraries(permissions PRIVATE Qt::QuickTemplates2)
+endif()
+
+set_target_properties(permissions PROPERTIES
+    MACOSX_BUNDLE TRUE
+    MACOSX_BUNDLE_INFO_PLIST "${CMAKE_CURRENT_SOURCE_DIR}/Info.plist"
+    MACOSX_BUNDLE_GUI_IDENTIFIER "io.qt.examples.qmlpermissions"
+    QT_ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android"
+)
+
+install(TARGETS permissions
+    BUNDLE  DESTINATION .
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+)
+
+qt_generate_deploy_qml_app_script(
+    TARGET permissions
+    OUTPUT_SCRIPT deploy_script
+    MACOS_BUNDLE_POST_BUILD
+    NO_UNSUPPORTED_PLATFORM_ERROR
+    DEPLOY_USER_QML_MODULES_ON_UNSUPPORTED_PLATFORM
+)
+install(SCRIPT ${deploy_script})