1 files changed, 83 insertions, 0 deletions
diff --git a/src/qmlmodels/doc/snippets/qml/tablemodel/fruit-example-delegatechooser.qml b/src/qmlmodels/doc/snippets/qml/tablemodel/fruit-example-delegatechooser.qml
new file mode 100644
index 0000000000..5241317c4d
--- /dev/null
+++ b/src/qmlmodels/doc/snippets/qml/tablemodel/fruit-example-delegatechooser.qml
@@ -0,0 +1,83 @@
+// Copyright (C) 2019 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+//![file]
+import QtQuick
+import QtQuick.Controls
+import Qt.labs.qmlmodels
+
+ApplicationWindow {
+    width: 400
+    height: 400
+    visible: true
+
+    TableView {
+        anchors.fill: parent
+        columnSpacing: 1
+        rowSpacing: 1
+        boundsBehavior: Flickable.StopAtBounds
+
+        model: TableModel {
+            TableModelColumn { display: "checked" }
+            TableModelColumn { display: "amount" }
+            TableModelColumn { display: "fruitType" }
+            TableModelColumn { display: "fruitName" }
+            TableModelColumn { display: "fruitPrice" }
+
+            // Each row is one type of fruit that can be ordered
+//![rows]
+            rows: [
+                {
+                    // Each property is one cell/column.
+                    checked: false,
+                    amount: 1,
+                    fruitType: "Apple",
+                    fruitName: "Granny Smith",
+                    fruitPrice: 1.50
+                },
+                {
+                    checked: true,
+                    amount: 4,
+                    fruitType: "Orange",
+                    fruitName: "Navel",
+                    fruitPrice: 2.50
+                },
+                {
+                    checked: false,
+                    amount: 1,
+                    fruitType: "Banana",
+                    fruitName: "Cavendish",
+                    fruitPrice: 3.50
+                }
+            ]
+//![rows]
+        }
+//![delegate]
+        delegate: DelegateChooser {
+            DelegateChoice {
+                column: 0
+                delegate: CheckBox {
+                    checked: model.display
+                    onToggled: model.display = checked
+                }
+            }
+            DelegateChoice {
+                column: 1
+                delegate: SpinBox {
+                    value: model.display
+                    onValueModified: model.display = value
+                }
+            }
+            DelegateChoice {
+                delegate: TextField {
+                    text: model.display
+                    selectByMouse: true
+                    implicitWidth: 140
+                    onAccepted: model.display = text
+                }
+            }
+        }
+//![delegate]
+    }
+}
+//![file]