1 files changed, 47 insertions, 0 deletions
diff --git a/src/quickcontrols/basic/Menu.qml b/src/quickcontrols/basic/Menu.qml
new file mode 100644
index 0000000000..8e08000337
--- /dev/null
+++ b/src/quickcontrols/basic/Menu.qml
@@ -0,0 +1,47 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Controls.impl
+import QtQuick.Templates as T
+
+T.Menu {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            contentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding)
+
+    margins: 0
+    overlap: 1
+
+    delegate: MenuItem { }
+
+    contentItem: ListView {
+        implicitHeight: contentHeight
+        model: control.contentModel
+        interactive: Window.window
+                     ? contentHeight + control.topPadding + control.bottomPadding > control.height
+                     : false
+        clip: true
+        currentIndex: control.currentIndex
+
+        ScrollIndicator.vertical: ScrollIndicator {}
+    }
+
+    background: Rectangle {
+        implicitWidth: 200
+        implicitHeight: 40
+        color: control.palette.window
+        border.color: control.palette.dark
+    }
+
+    T.Overlay.modal: Rectangle {
+        color: Color.transparent(control.palette.shadow, 0.5)
+    }
+
+    T.Overlay.modeless: Rectangle {
+        color: Color.transparent(control.palette.shadow, 0.12)
+    }
+}