1 files changed, 72 insertions, 0 deletions
diff --git a/src/quickcontrols/doc/snippets/qtquickcontrols-spinbox-custom.qml b/src/quickcontrols/doc/snippets/qtquickcontrols-spinbox-custom.qml
new file mode 100644
index 0000000000..c2e6452da6
--- /dev/null
+++ b/src/quickcontrols/doc/snippets/qtquickcontrols-spinbox-custom.qml
@@ -0,0 +1,72 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+//! [file]
+import QtQuick
+import QtQuick.Controls
+
+SpinBox {
+    id: control
+    value: 50
+    editable: true
+
+    contentItem: TextInput {
+        z: 2
+        text: control.textFromValue(control.value, control.locale)
+
+        font: control.font
+        color: "#21be2b"
+        selectionColor: "#21be2b"
+        selectedTextColor: "#ffffff"
+        horizontalAlignment: Qt.AlignHCenter
+        verticalAlignment: Qt.AlignVCenter
+
+        readOnly: !control.editable
+        validator: control.validator
+        inputMethodHints: Qt.ImhFormattedNumbersOnly
+    }
+
+    up.indicator: Rectangle {
+        x: control.mirrored ? 0 : parent.width - width
+        height: parent.height
+        implicitWidth: 40
+        implicitHeight: 40
+        color: control.up.pressed ? "#e4e4e4" : "#f6f6f6"
+        border.color: enabled ? "#21be2b" : "#bdbebf"
+
+        Text {
+            text: "+"
+            font.pixelSize: control.font.pixelSize * 2
+            color: "#21be2b"
+            anchors.fill: parent
+            fontSizeMode: Text.Fit
+            horizontalAlignment: Text.AlignHCenter
+            verticalAlignment: Text.AlignVCenter
+        }
+    }
+
+    down.indicator: Rectangle {
+        x: control.mirrored ? parent.width - width : 0
+        height: parent.height
+        implicitWidth: 40
+        implicitHeight: 40
+        color: control.down.pressed ? "#e4e4e4" : "#f6f6f6"
+        border.color: enabled ? "#21be2b" : "#bdbebf"
+
+        Text {
+            text: "-"
+            font.pixelSize: control.font.pixelSize * 2
+            color: "#21be2b"
+            anchors.fill: parent
+            fontSizeMode: Text.Fit
+            horizontalAlignment: Text.AlignHCenter
+            verticalAlignment: Text.AlignVCenter
+        }
+    }
+
+    background: Rectangle {
+        implicitWidth: 140
+        border.color: "#bdbebf"
+    }
+}
+//! [file]