1 files changed, 146 insertions, 0 deletions
diff --git a/src/quickcontrols/fusion/ComboBox.qml b/src/quickcontrols/fusion/ComboBox.qml
new file mode 100644
index 0000000000..55d91e65ed
--- /dev/null
+++ b/src/quickcontrols/fusion/ComboBox.qml
@@ -0,0 +1,146 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Window
+import QtQuick.Templates as T
+import QtQuick.Controls.impl
+import QtQuick.Controls.Fusion
+import QtQuick.Controls.Fusion.impl
+
+T.ComboBox {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding,
+                             implicitIndicatorHeight + topPadding + bottomPadding)
+
+    leftPadding: padding + (!control.mirrored || !indicator || !indicator.visible ? 0 : indicator.width + spacing)
+    rightPadding: padding + (control.mirrored || !indicator || !indicator.visible ? 0 : indicator.width + spacing)
+
+    delegate: MenuItem {
+        required property var model
+        required property int index
+
+        width: ListView.view.width
+        text: model[control.textRole]
+        font.weight: control.currentIndex === index ? Font.DemiBold : Font.Normal
+        highlighted: control.highlightedIndex === index
+        hoverEnabled: control.hoverEnabled
+    }
+
+    indicator: ColorImage {
+        x: control.mirrored ? control.padding : control.width - width - control.padding
+        y: control.topPadding + (control.availableHeight - height) / 2
+        color: control.editable ? control.palette.text : control.palette.buttonText
+        source: "qrc:/qt-project.org/imports/QtQuick/Controls/Fusion/images/arrow.png"
+        width: 20
+        fillMode: Image.Pad
+    }
+
+    contentItem: T.TextField {
+        topPadding: 4
+        leftPadding: 4 - control.padding
+        rightPadding: 4 - control.padding
+        bottomPadding: 4
+
+        text: control.editable ? control.editText : control.displayText
+
+        enabled: control.editable
+        autoScroll: control.editable
+        readOnly: control.down
+        inputMethodHints: control.inputMethodHints
+        validator: control.validator
+        selectByMouse: control.selectTextByMouse
+
+        color: control.editable ? control.palette.text : control.palette.buttonText
+        selectionColor: control.palette.highlight
+        selectedTextColor: control.palette.highlightedText
+        verticalAlignment: Text.AlignVCenter
+
+        background: PaddedRectangle {
+            clip: true
+            radius: 2
+            padding: 1
+            leftPadding: control.mirrored ? -2 : padding
+            rightPadding: !control.mirrored ? -2 : padding
+            color: control.palette.base
+            visible: control.editable && !control.flat
+
+            Rectangle {
+                x: parent.width - width
+                y: 1
+                width: 1
+                height: parent.height - 2
+                color: Fusion.buttonOutline(control.palette, control.activeFocus, control.enabled)
+            }
+
+            Rectangle {
+                x: 1
+                y: 1
+                width: parent.width - 3
+                height: 1
+                color: Fusion.topShadow
+            }
+        }
+
+        Rectangle {
+            x: 1 - control.leftPadding
+            y: 1
+            width: control.width - 2
+            height: control.height - 2
+            color: "transparent"
+            border.color: Color.transparent(Fusion.highlightedOutline(control.palette), 40 / 255)
+            visible: control.activeFocus
+            radius: 1.7
+        }
+    }
+
+    background: ButtonPanel {
+        implicitWidth: 120
+        implicitHeight: 24
+
+        control: control
+        visible: !control.flat || control.down
+        // ### TODO: fix control.contentItem.activeFocus
+        highlighted: control.visualFocus || control.contentItem.activeFocus
+    }
+
+    popup: T.Popup {
+        width: control.width
+        height: Math.min(contentItem.implicitHeight + 2, control.Window.height - topMargin - bottomMargin)
+        topMargin: 6
+        bottomMargin: 6
+        padding: 1
+        palette: control.palette
+
+        contentItem: ListView {
+            clip: true
+            implicitHeight: contentHeight
+            model: control.delegateModel
+            currentIndex: control.highlightedIndex
+            highlightRangeMode: ListView.ApplyRange
+            highlightMoveDuration: 0
+
+            T.ScrollBar.vertical: ScrollBar { }
+        }
+
+        background: Rectangle {
+            color: palette.window
+            border.color: Fusion.outline(palette)
+
+            Rectangle {
+                z: -1
+                x: 1; y: 1
+                width: parent.width
+                height: parent.height
+                color: palette.shadow
+                opacity: 0.2
+            }
+        }
+    }
+}