1 files changed, 104 insertions, 0 deletions
diff --git a/src/quickcontrols/imagine/DelayButton.qml b/src/quickcontrols/imagine/DelayButton.qml
new file mode 100644
index 0000000000..73854cdd33
--- /dev/null
+++ b/src/quickcontrols/imagine/DelayButton.qml
@@ -0,0 +1,104 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.DelayButton {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    transition: Transition {
+        NumberAnimation {
+            duration: control.delay * (control.pressed ? 1.0 - control.progress : 0.3 * control.progress)
+        }
+    }
+
+    contentItem: Text {
+        text: control.text
+        font: control.font
+        color: control.palette.buttonText
+        horizontalAlignment: Text.AlignHCenter
+        verticalAlignment: Text.AlignVCenter
+        elide: Text.ElideRight
+    }
+
+    background: NinePatchImage {
+        source: control.Imagine.url + "delaybutton-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"pressed": control.down},
+                {"checked": control.checked},
+                {"focused": control.visualFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+
+        readonly property NinePatchImage progress: NinePatchImage {
+            parent: control.background
+            width: control.progress * parent.width
+            height: parent.height
+            visible: false
+
+            source: control.Imagine.url + "delaybutton-progress"
+            NinePatchImageSelector on source {
+                states: [
+                    {"disabled": !control.enabled},
+                    {"pressed": control.down},
+                    {"checked": control.checked},
+                    {"focused": control.visualFocus},
+                    {"mirrored": control.mirrored},
+                    {"hovered": control.enabled && control.hovered}
+                ]
+            }
+        }
+
+        readonly property NinePatchImage mask: NinePatchImage {
+            width: control.background.width
+            height: control.background.height
+            visible: false
+
+            source: control.Imagine.url + "delaybutton-mask"
+            NinePatchImageSelector on source {
+                states: [
+                    {"disabled": !control.enabled},
+                    {"pressed": control.down},
+                    {"checked": control.checked},
+                    {"focused": control.visualFocus},
+                    {"mirrored": control.mirrored},
+                    {"hovered": control.enabled && control.hovered}
+                ]
+            }
+        }
+
+        readonly property OpacityMask effect: OpacityMask {
+            parent: control.background
+            width: source.width
+            height: source.height
+            source: control.background.progress
+
+            maskSource: ShaderEffectSource {
+                sourceItem: control.background.mask
+                sourceRect: Qt.rect(0, 0, control.background.effect.width, control.background.effect.height)
+            }
+        }
+    }
+}