1 files changed, 68 insertions, 0 deletions
diff --git a/src/quickcontrols/imagine/Dial.qml b/src/quickcontrols/imagine/Dial.qml
new file mode 100644
index 0000000000..d534fad44e
--- /dev/null
+++ b/src/quickcontrols/imagine/Dial.qml
@@ -0,0 +1,68 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.Dial {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                           (handle ? handle.implicitWidth : 0) + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                            (handle ? handle.implicitHeight : 0) + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    handle: Image {
+        x: control.background.x + control.background.width / 2 - width / 2
+        y: control.background.y + control.background.height / 2 - height / 2
+
+        source: Imagine.url + "dial-handle"
+        ImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"pressed": control.pressed},
+                {"focused": control.visualFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+
+        transform: [
+            Translate {
+                y: -Math.min(control.background.width, control.background.height) * 0.4
+                   + (control.handle ? control.handle.height / 2 : 0)
+            },
+            Rotation {
+                angle: control.angle
+                origin.x: control.handle ? control.handle.width / 2 : 0
+                origin.y: control.handle ? control.handle.height / 2 : 0
+            }
+        ]
+    }
+
+    background: NinePatchImage {
+        fillMode: Image.PreserveAspectFit
+        source: Imagine.url + "dial-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"pressed": control.pressed},
+                {"focused": control.visualFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+    }
+}