1 files changed, 52 insertions, 0 deletions
diff --git a/src/quickcontrols/imagine/DialogButtonBox.qml b/src/quickcontrols/imagine/DialogButtonBox.qml
new file mode 100644
index 0000000000..81d87b65df
--- /dev/null
+++ b/src/quickcontrols/imagine/DialogButtonBox.qml
@@ -0,0 +1,52 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.DialogButtonBox {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            (control.count === 1 ? contentWidth * 2 : contentWidth) + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    spacing: 6
+
+    delegate: Button {
+        width: control.count === 1 ? control.availableWidth / 2 : undefined
+        flat: true
+    }
+
+    contentItem: ListView {
+        implicitWidth: contentWidth
+        model: control.contentModel
+        spacing: control.spacing
+        orientation: ListView.Horizontal
+        boundsBehavior: Flickable.StopAtBounds
+        snapMode: ListView.SnapToItem
+    }
+
+    background: NinePatchImage {
+        source: Imagine.url + "dialogbuttonbox-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"mirrored": control.mirrored}
+            ]
+        }
+    }
+}