1 files changed, 59 insertions, 0 deletions
diff --git a/src/quickcontrols/imagine/PageIndicator.qml b/src/quickcontrols/imagine/PageIndicator.qml
new file mode 100644
index 0000000000..42afbda70a
--- /dev/null
+++ b/src/quickcontrols/imagine/PageIndicator.qml
@@ -0,0 +1,59 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.PageIndicator {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    delegate: Image {
+        source: Imagine.url + "pageindicator-delegate"
+        ImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"pressed": pressed},
+                {"current": index === control.currentIndex},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered} // ### TODO: context property
+            ]
+        }
+    }
+
+    contentItem: Row {
+        spacing: control.spacing
+
+        Repeater {
+            model: control.count
+            delegate: control.delegate
+        }
+    }
+
+    background: NinePatchImage {
+        source: Imagine.url + "pageindicator-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+    }
+}