1 files changed, 64 insertions, 0 deletions
diff --git a/src/quickcontrols/imagine/RoundButton.qml b/src/quickcontrols/imagine/RoundButton.qml
new file mode 100644
index 0000000000..2000d92f85
--- /dev/null
+++ b/src/quickcontrols/imagine/RoundButton.qml
@@ -0,0 +1,64 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.impl
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.RoundButton {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    icon.width: 24
+    icon.height: 24
+    icon.color: control.enabled && control.flat && control.highlighted ? control.palette.highlight
+        : control.enabled && (control.down || control.checked || control.highlighted) && !control.flat
+        ? control.palette.brightText : control.flat ? control.palette.windowText : control.palette.buttonText
+
+    contentItem: IconLabel {
+        spacing: control.spacing
+        mirrored: control.mirrored
+        display: control.display
+
+        icon: control.icon
+        text: control.text
+        font: control.font
+        color: control.enabled && control.flat && control.highlighted ? control.palette.highlight
+            : control.enabled && (control.down || control.checked || control.highlighted) && !control.flat
+            ? control.palette.brightText : control.flat ? control.palette.windowText : control.palette.buttonText
+    }
+
+    background: NinePatchImage {
+        // ### TODO: radius?
+        source: Imagine.url + "roundbutton-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"disabled": !control.enabled},
+                {"pressed": control.down},
+                {"checked": control.checked},
+                {"checkable": control.checkable},
+                {"focused": control.visualFocus},
+                {"highlighted": control.highlighted},
+                {"flat": control.flat},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+    }
+}