1 files changed, 90 insertions, 0 deletions
diff --git a/src/quickcontrols/imagine/Slider.qml b/src/quickcontrols/imagine/Slider.qml
new file mode 100644
index 0000000000..8176abcd78
--- /dev/null
+++ b/src/quickcontrols/imagine/Slider.qml
@@ -0,0 +1,90 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Imagine
+import QtQuick.Controls.Imagine.impl
+
+T.Slider {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitHandleWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitHandleHeight + topPadding + bottomPadding)
+
+    topPadding: background ? background.topPadding : 0
+    leftPadding: background ? background.leftPadding : 0
+    rightPadding: background ? background.rightPadding : 0
+    bottomPadding: background ? background.bottomPadding : 0
+
+    topInset: background ? -background.topInset || 0 : 0
+    leftInset: background ? -background.leftInset || 0 : 0
+    rightInset: background ? -background.rightInset || 0 : 0
+    bottomInset: background ? -background.bottomInset || 0 : 0
+
+    handle: Image {
+        x: Math.round(control.leftPadding + (control.horizontal ? control.visualPosition * (control.availableWidth - width) : (control.availableWidth - width) / 2))
+        y: Math.round(control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : control.visualPosition * (control.availableHeight - height)))
+
+        source: control.Imagine.url + "slider-handle"
+        ImageSelector on source {
+            states: [
+                {"vertical": control.vertical},
+                {"horizontal": control.horizontal},
+                {"disabled": !control.enabled},
+                {"pressed": control.pressed},
+                {"focused": control.visualFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+    }
+
+    background: NinePatchImage {
+        scale: control.horizontal && control.mirrored ? -1 : 1
+
+        source: control.Imagine.url + "slider-background"
+        NinePatchImageSelector on source {
+            states: [
+                {"vertical": control.vertical},
+                {"horizontal": control.horizontal},
+                {"disabled": !control.enabled},
+                {"pressed": control.down},
+                {"focused": control.visualFocus},
+                {"mirrored": control.mirrored},
+                {"hovered": control.enabled && control.hovered}
+            ]
+        }
+
+        NinePatchImage {
+            readonly property real handleWidth: control.handle ? control.handle.width : 0
+            readonly property real handleHeight: control.handle ? control.handle.height : 0
+
+            x: control.horizontal ? 0 : (parent.width - width) / 2
+            y: control.horizontal
+               ? (parent.height - height) / 2
+               : handleHeight / 2 + control.visualPosition * (parent.height - handleHeight)
+            width: control.horizontal
+                ? handleWidth / 2 + control.position * (parent.width - handleWidth)
+                : parent.width
+            height: control.vertical
+                ? handleHeight / 2 + control.position * (parent.height - handleHeight)
+                : parent.height
+
+            source: control.Imagine.url + "slider-progress"
+            NinePatchImageSelector on source {
+                states: [
+                    {"vertical": control.vertical},
+                    {"horizontal": control.horizontal},
+                    {"disabled": !control.enabled},
+                    {"pressed": control.down},
+                    {"focused": control.visualFocus},
+                    {"mirrored": control.mirrored},
+                    {"hovered": control.enabled && control.hovered}
+                ]
+            }
+        }
+    }
+}