1 files changed, 74 insertions, 0 deletions
diff --git a/src/quickcontrols/ios/Dialog.qml b/src/quickcontrols/ios/Dialog.qml
new file mode 100644
index 0000000000..f8f400daf1
--- /dev/null
+++ b/src/quickcontrols/ios/Dialog.qml
@@ -0,0 +1,74 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.impl
+import QtQuick.Controls.iOS.impl
+
+T.Dialog {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            contentWidth + leftPadding + rightPadding,
+                            implicitHeaderWidth,
+                            implicitFooterWidth)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding
+                             + (implicitHeaderHeight > 0 ? implicitHeaderHeight + spacing : 0)
+                             + (implicitFooterHeight > 0 ? implicitFooterHeight + spacing : 0))
+    leftPadding: 16
+    rightPadding: 16
+    bottomPadding: 23
+
+    dim: true
+
+    enter: Transition {
+        NumberAnimation { property: "scale"; from: 1.5; to: 1.0; easing.type: Easing.OutQuint; duration: 220 }
+        NumberAnimation { property: "opacity"; from: 0.0; to: 1.0; easing.type: Easing.OutCubic; duration: 150 }
+    }
+
+    exit: Transition {
+        NumberAnimation { property: "opacity"; from: 1.0; to: 0.0; easing.type: Easing.OutCubic; duration: 150 }
+    }
+
+    background: Item {
+        NinePatchImage {
+            width: parent.width
+            height: parent.height
+            source: IOS.url + "popup-background"
+            NinePatchImageSelector on source {
+                states: [
+                    {"light": Qt.styleHints.colorScheme === Qt.Light},
+                    {"dark": Qt.styleHints.colorScheme === Qt.Dark}
+                ]
+            }
+        }
+    }
+
+    header: Label {
+        text: control.title
+        visible: control.title
+        horizontalAlignment: Text.AlignHCenter
+        topPadding: 23
+        bottomPadding: 7
+        verticalAlignment: Text.AlignVCenter
+        elide: Label.ElideRight
+        font.weight: Font.Medium
+        font.pointSize: 17
+    }
+
+    footer: DialogButtonBox {
+        visible: count > 0
+    }
+
+    T.Overlay.modal: Rectangle {
+        color: Color.transparent("black", 0.5)
+        Behavior on opacity { NumberAnimation { duration: 150 } }
+    }
+
+    T.Overlay.modeless: Rectangle {
+        color: Color.transparent("black", 0.5)
+        Behavior on opacity { NumberAnimation { duration: 150 } }
+    }
+}