1 files changed, 53 insertions, 0 deletions
diff --git a/src/quickcontrols/material/Dial.qml b/src/quickcontrols/material/Dial.qml
new file mode 100644
index 0000000000..465c1f3631
--- /dev/null
+++ b/src/quickcontrols/material/Dial.qml
@@ -0,0 +1,53 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Material
+import QtQuick.Controls.Material.impl
+
+T.Dial {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    background: Rectangle {
+        implicitWidth: 100
+        implicitHeight: 100
+
+        x: control.width / 2 - width / 2
+        y: control.height / 2 - height / 2
+        width: Math.max(64, Math.min(control.width, control.height))
+        height: width
+        color: "transparent"
+        radius: width / 2
+
+        border.color: control.enabled ? control.Material.accentColor : control.Material.hintTextColor
+    }
+
+    handle: SliderHandle {
+        x: control.background.x + control.background.width / 2 - width / 2
+        y: control.background.y + control.background.height / 2 - height / 2
+        transform: [
+            Translate {
+                y: -control.background.height * 0.4
+                   + (control.handle ? control.handle.height / 2 : 0)
+            },
+            Rotation {
+                angle: control.angle
+                origin.x: control.handle ? control.handle.width / 2 : 0
+                origin.y: control.handle ? control.handle.height / 2 : 0
+            }
+        ]
+        implicitWidth: 10
+        implicitHeight: 10
+
+        value: control.value
+        handleHasFocus: control.visualFocus
+        handlePressed: control.pressed
+        handleHovered: control.hovered
+    }
+}