1 files changed, 51 insertions, 0 deletions
diff --git a/src/quickcontrols/material/GroupBox.qml b/src/quickcontrols/material/GroupBox.qml
new file mode 100644
index 0000000000..f0cee7c854
--- /dev/null
+++ b/src/quickcontrols/material/GroupBox.qml
@@ -0,0 +1,51 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Material
+import QtQuick.Controls.Material.impl
+
+T.GroupBox {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            contentWidth + leftPadding + rightPadding,
+                            implicitLabelWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding)
+
+    spacing: 6
+    padding: 12
+    topPadding: Material.frameVerticalPadding + (implicitLabelWidth > 0 ? implicitLabelHeight + spacing : 0)
+    bottomPadding: Material.frameVerticalPadding
+
+    Material.roundedScale: Material.ExtraSmallScale
+
+    label: Text {
+        x: Math.max(control.leftPadding, control.Material.roundedScale)
+        width: control.availableWidth
+
+        text: control.title
+        font: control.font
+        color: control.enabled ? control.Material.foreground : control.Material.hintTextColor
+        elide: Text.ElideRight
+        verticalAlignment: Text.AlignVCenter
+    }
+
+    background: Rectangle {
+        y: control.topPadding - control.bottomPadding
+        width: parent.width
+        height: parent.height - control.topPadding + control.bottomPadding
+
+        radius: control.Material.roundedScale
+        color: control.Material.elevation > 0 ? control.Material.backgroundColor : "transparent"
+        border.color: control.Material.frameColor
+
+        layer.enabled: control.enabled && control.Material.elevation > 0
+        layer.effect: RoundedElevationEffect {
+            elevation: control.Material.elevation
+            roundedScale: control.background.radius
+        }
+    }
+}