1 files changed, 61 insertions, 0 deletions
diff --git a/src/quickcontrols/universal/DelayButton.qml b/src/quickcontrols/universal/DelayButton.qml
new file mode 100644
index 0000000000..2b2cc83580
--- /dev/null
+++ b/src/quickcontrols/universal/DelayButton.qml
@@ -0,0 +1,61 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Universal
+
+T.DelayButton {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    padding: 8
+    verticalPadding: padding - 4
+
+    property bool useSystemFocusVisuals: true
+
+    transition: Transition {
+        NumberAnimation {
+            duration: control.delay * (control.pressed ? 1.0 - control.progress : 0.3 * control.progress)
+        }
+    }
+
+    contentItem: Text {
+        text: control.text
+        font: control.font
+        elide: Text.ElideRight
+        horizontalAlignment: Text.AlignHCenter
+        verticalAlignment: Text.AlignVCenter
+
+        opacity: enabled ? 1.0 : 0.2
+        color: control.Universal.foreground
+    }
+
+    background: Rectangle {
+        implicitWidth: 32
+        implicitHeight: 32
+
+        color: control.down ? control.Universal.baseMediumLowColor :
+               control.enabled && control.checked ? control.Universal.accent : control.Universal.baseLowColor
+
+        Rectangle {
+            visible: !control.checked
+            width: parent.width * control.progress
+            height: parent.height
+            color: control.Universal.accent
+        }
+
+        Rectangle {
+            width: parent.width
+            height: parent.height
+            color: "transparent"
+            visible: enabled && control.hovered
+            border.width: 2 // ButtonBorderThemeThickness
+            border.color: control.Universal.baseMediumLowColor
+        }
+    }
+}