1 files changed, 57 insertions, 0 deletions
diff --git a/src/quickcontrols/universal/MenuBarItem.qml b/src/quickcontrols/universal/MenuBarItem.qml
new file mode 100644
index 0000000000..84dfb22fad
--- /dev/null
+++ b/src/quickcontrols/universal/MenuBarItem.qml
@@ -0,0 +1,57 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.impl
+import QtQuick.Controls.Universal
+
+T.MenuBarItem {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding,
+                             implicitIndicatorHeight + topPadding + bottomPadding)
+
+    padding: 12
+    topPadding: padding - 1
+    bottomPadding: padding + 1
+    spacing: 12
+
+    icon.width: 20
+    icon.height: 20
+    icon.color: !enabled ? Universal.baseLowColor : Universal.baseHighColor
+
+    contentItem: IconLabel {
+        spacing: control.spacing
+        mirrored: control.mirrored
+        display: control.display
+        alignment: Qt.AlignLeft
+
+        icon: control.icon
+        text: control.text
+        font: control.font
+        color: !control.enabled ? control.Universal.baseLowColor : control.Universal.baseHighColor
+    }
+
+    background: Rectangle {
+        implicitWidth: 40
+        implicitHeight: 40
+
+        color: !control.enabled ? control.Universal.baseLowColor :
+                control.down ? control.Universal.listMediumColor :
+                control.highlighted ? control.Universal.listLowColor : "transparent"
+
+        Rectangle {
+            x: 1; y: 1
+            width: parent.width - 2
+            height: parent.height - 2
+
+            visible: control.visualFocus
+            color: control.Universal.accent
+            opacity: control.Universal.theme === Universal.Light ? 0.4 : 0.6
+        }
+    }
+}