1 files changed, 61 insertions, 0 deletions
diff --git a/src/quickcontrols/universal/ScrollBar.qml b/src/quickcontrols/universal/ScrollBar.qml
new file mode 100644
index 0000000000..a5ab5fc762
--- /dev/null
+++ b/src/quickcontrols/universal/ScrollBar.qml
@@ -0,0 +1,61 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Universal
+
+T.ScrollBar {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding)
+
+    visible: control.policy !== T.ScrollBar.AlwaysOff
+    minimumSize: orientation === Qt.Horizontal ? height / width : width / height
+
+    // TODO: arrows
+
+    contentItem: Rectangle {
+        implicitWidth: control.interactive ? 12 : 6
+        implicitHeight: control.interactive ? 12: 6
+
+        color: control.pressed ? control.Universal.baseMediumColor :
+               enabled && control.interactive && control.hovered ? control.Universal.baseMediumLowColor :
+               control.Universal.chromeHighColor
+        opacity: 0.0
+    }
+
+    background: Rectangle {
+        implicitWidth: control.interactive ? 12 : 6
+        implicitHeight: control.interactive ? 12: 6
+
+        color: control.Universal.chromeLowColor
+        visible: control.size < 1.0
+        opacity: 0.0
+    }
+
+    states: [
+        State {
+            name: "active"
+            when: control.policy === T.ScrollBar.AlwaysOn || (control.active && control.size < 1.0)
+        }
+    ]
+
+    transitions: [
+        Transition {
+            to: "active"
+            NumberAnimation { targets: [control.contentItem, control.background]; property: "opacity"; to: 1.0 }
+        },
+        Transition {
+            from: "active"
+            SequentialAnimation {
+                PropertyAction{ targets: [control.contentItem, control.background]; property: "opacity"; value: 1.0 }
+                PauseAnimation { duration: 3000 }
+                NumberAnimation { targets: [control.contentItem, control.background]; property: "opacity"; to: 0.0 }
+            }
+        }
+    ]
+}