1 files changed, 63 insertions, 0 deletions
diff --git a/src/quickcontrols/universal/Slider.qml b/src/quickcontrols/universal/Slider.qml
new file mode 100644
index 0000000000..305c5c321f
--- /dev/null
+++ b/src/quickcontrols/universal/Slider.qml
@@ -0,0 +1,63 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.Universal
+
+T.Slider {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitHandleWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitHandleHeight + topPadding + bottomPadding)
+
+    padding: 6
+
+    property bool useSystemFocusVisuals: true
+
+    handle: Rectangle {
+        implicitWidth: control.horizontal ? 8 : 24
+        implicitHeight: control.horizontal ? 24 : 8
+
+        x: control.leftPadding + (control.horizontal ? control.visualPosition * (control.availableWidth - width) : (control.availableWidth - width) / 2)
+        y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : control.visualPosition * (control.availableHeight - height))
+
+        radius: 4
+        color: control.pressed ? control.Universal.chromeHighColor :
+               control.enabled ? control.hovered ? control.Universal.chromeAltLowColor :
+               control.Universal.accent : control.Universal.chromeDisabledHighColor
+    }
+
+    background: Item {
+        implicitWidth: control.horizontal ? 200 : 18
+        implicitHeight: control.horizontal ? 18 : 200
+
+        x: control.leftPadding + (control.horizontal ? 0 : (control.availableWidth - width) / 2)
+        y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : 0)
+        width: control.horizontal ? control.availableWidth : implicitWidth
+        height: control.horizontal ? implicitHeight : control.availableHeight
+
+        scale: control.horizontal && control.mirrored ? -1 : 1
+
+        Rectangle {
+            x: control.horizontal ? 0 : (parent.width - width) / 2
+            y: control.horizontal ? (parent.height - height) / 2 : 0
+            width: control.horizontal ? parent.width : 2 // SliderTrackThemeHeight
+            height: !control.horizontal ? parent.height : 2 // SliderTrackThemeHeight
+
+            color: enabled && control.hovered && !control.pressed ? control.Universal.baseMediumColor :
+                   control.enabled ? control.Universal.baseMediumLowColor : control.Universal.chromeDisabledHighColor
+        }
+
+        Rectangle {
+            x: control.horizontal ? 0 : (parent.width - width) / 2
+            y: control.horizontal ? (parent.height - height) / 2 : control.visualPosition * parent.height
+            width: control.horizontal ? control.position * parent.width : 2 // SliderTrackThemeHeight
+            height: !control.horizontal ? control.position * parent.height : 2 // SliderTrackThemeHeight
+
+            color: control.enabled ? control.Universal.accent : control.Universal.chromeDisabledHighColor
+        }
+    }
+}