1 files changed, 115 insertions, 0 deletions
diff --git a/src/quickdialogs/quickdialogsquickimpl/qml/FontDialog.qml b/src/quickdialogs/quickdialogsquickimpl/qml/FontDialog.qml
new file mode 100644
index 0000000000..2643b88e3b
--- /dev/null
+++ b/src/quickdialogs/quickdialogsquickimpl/qml/FontDialog.qml
@@ -0,0 +1,115 @@
+// Copyright (C) 2021 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Controls.impl
+import QtQuick.Dialogs
+import QtQuick.Dialogs.quickimpl
+import QtQuick.Layouts
+import QtQuick.Templates as T
+
+FontDialogImpl {
+    id: control
+
+    implicitWidth: Math.max(control.implicitBackgroundWidth + control.leftInset + control.rightInset,
+                            control.contentWidth + control.leftPadding + control.rightPadding,
+                            control.implicitHeaderWidth,
+                            control.implicitFooterWidth)
+    implicitHeight: Math.max(control.implicitBackgroundHeight + control.topInset + control.bottomInset,
+                             control.contentHeight + control.topPadding + control.bottomPadding
+                             + (control.implicitHeaderHeight > 0 ? control.implicitHeaderHeight + control.spacing : 0)
+                             + (control.implicitFooterHeight > 0 ? control.implicitFooterHeight + control.spacing : 0))
+
+    leftPadding: 20
+    rightPadding: 20
+    // Ensure that the background's border is visible.
+    leftInset: -1
+    rightInset: -1
+    topInset: -1
+    bottomInset: -1
+
+    spacing: 12
+
+    standardButtons: T.Dialog.Ok | T.Dialog.Cancel
+
+    FontDialogImpl.buttonBox: buttonBox
+    FontDialogImpl.familyListView: content.familyListView
+    FontDialogImpl.styleListView: content.styleListView
+    FontDialogImpl.sizeListView: content.sizeListView
+    FontDialogImpl.sampleEdit: content.sampleEdit
+    FontDialogImpl.writingSystemComboBox: writingSystemComboBox
+    FontDialogImpl.underlineCheckBox: content.underline
+    FontDialogImpl.strikeoutCheckBox: content.strikeout
+    FontDialogImpl.familyEdit: content.familyEdit
+    FontDialogImpl.styleEdit: content.styleEdit
+    FontDialogImpl.sizeEdit: content.sizeEdit
+
+    background: Rectangle {
+        implicitWidth: 600
+        implicitHeight: 400
+        color: control.palette.window
+        border.color: control.palette.dark
+    }
+
+    Overlay.modal: Rectangle {
+        color: Color.transparent(control.palette.shadow, 0.5)
+    }
+
+    Overlay.modeless: Rectangle {
+        color: Color.transparent(control.palette.shadow, 0.12)
+    }
+
+    header: Pane {
+        palette.window: control.palette.light
+        padding: 20
+
+        contentItem: Label {
+            width: parent.width
+            text: control.title
+            visible: control.title.length > 0
+            horizontalAlignment: Label.AlignHCenter
+            elide: Label.ElideRight
+            font.bold: true
+        }
+    }
+
+    contentItem: FontDialogContent {
+        id: content
+    }
+
+    footer: Rectangle {
+        color: control.palette.light
+        implicitWidth: rowLayout.implicitWidth
+        implicitHeight: rowLayout.implicitHeight
+
+        RowLayout {
+            id: rowLayout
+            width: parent.width
+            height: parent.height
+            spacing: 20
+
+            Label {
+                text: qsTr("Writing System")
+
+                Layout.leftMargin: 20
+            }
+            ComboBox{
+                id: writingSystemComboBox
+
+                Layout.fillWidth: true
+            }
+
+            DialogButtonBox {
+                id: buttonBox
+                standardButtons: control.standardButtons
+                palette.window: control.palette.light
+                spacing: 12
+                horizontalPadding: 0
+                verticalPadding: 20
+
+                Layout.rightMargin: 20
+            }
+        }
+    }
+}