1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
|
// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtQuick.Controls
import "../"
Item {
id: root
width: 320
height: 480
Column {
spacing: 5
anchors {
fill: parent
topMargin: 12
}
Label {
anchors.horizontalCenter: parent.horizontalCenter
text: qsTr("Bezier Curve")
color: Qt.lighter(palette.text)
font {
pointSize: 24
bold: true
}
}
Canvas {
id: canvas
readonly property color strokeStyle: Qt.darker(fillStyle, 1.4)
readonly property color fillStyle: "#b40000" // red
readonly property alias lineWidth: lineWidthCtrl.value
readonly property alias fill: toggleFillCheckBox.checked
readonly property alias stroke: toggleStrokeCheckBox.checked
readonly property real alpha: 1.0
readonly property alias scale: scaleCtrl.value
readonly property alias rotate: rotateCtrl.value
width: root.width
height: parent.height - controls.height
antialiasing: true
onLineWidthChanged: requestPaint()
onFillChanged: requestPaint()
onStrokeChanged: requestPaint()
onScaleChanged: requestPaint()
onRotateChanged: requestPaint()
onPaint: function() {
let ctx = canvas.getContext('2d')
const originX = 85
const originY = 75
ctx.save()
ctx.clearRect(0, 0, canvas.width, canvas.height)
ctx.translate(originX, originX)
ctx.globalAlpha = canvas.alpha
ctx.strokeStyle = canvas.strokeStyle
ctx.fillStyle = canvas.fillStyle
ctx.lineWidth = canvas.lineWidth
ctx.translate(originX, originY)
ctx.scale(canvas.scale, canvas.scale)
ctx.rotate(canvas.rotate)
ctx.translate(-originX, -originY)
//! [0]
ctx.beginPath()
ctx.moveTo(75,40)
ctx.bezierCurveTo(75,37,70,25,50,25)
ctx.bezierCurveTo(20,25,20,62.5,20,62.5)
ctx.bezierCurveTo(20,80,40,102,75,120)
ctx.bezierCurveTo(110,102,130,80,130,62.5)
ctx.bezierCurveTo(130,62.5,130,25,100,25)
ctx.bezierCurveTo(85,25,75,37,75,40)
ctx.closePath()
//! [0]
if (canvas.fill)
ctx.fill()
if (canvas.stroke)
ctx.stroke()
ctx.restore()
}
}
}
Column {
id: controls
anchors {
bottom: parent.bottom
bottomMargin: 12
}
LabeledSlider {
id: lineWidthCtrl
name: qsTr("Outline")
min: 1
max: 10
value: 2
width: root.width
}
LabeledSlider {
id: scaleCtrl
name: qsTr("Scale")
min: 0.1
max: 10
value: 1
width: root.width
}
LabeledSlider {
id: rotateCtrl
name: qsTr("Rotate")
min: 0
max: Math.PI * 2
value: 0
width: root.width
}
Row {
CheckBox {
id: toggleFillCheckBox
checked: true
text: qsTr("Toggle fill")
}
CheckBox {
id: toggleStrokeCheckBox
checked: true
text: qsTr("Toggle stroke")
}
}
}
}
|