examples/quick/shapes/gradientSpreadModes.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick
import QtQuick.Shapes

Rectangle {
    color: "lightGray"
    width: 256
    height: 256
    Rectangle {
        border.color: "black"
        width: 200
        height: 200
        anchors.centerIn: parent

        Shape {
            anchors.fill: parent

            ShapePath {
                strokeColor: "transparent"

                fillGradient: LinearGradient {
                    id: grad
                    y1: 50; y2: 150
                    GradientStop { position: 0; color: "black" }
                    GradientStop { position: 1; color: "red" }
                }

                startX: 10; startY: 10
                PathLine { relativeX: 180; relativeY: 0 }
                PathLine { relativeX: 0; relativeY: 180 }
                PathLine { relativeX: -180; relativeY: 0 }
                PathLine { relativeX: 0; relativeY: -180 }
            }
        }

        Timer {
            id: spreadTimer
            interval: 3000
            running: true
            repeat: true
            property variant spreads: [ ShapeGradient.PadSpread, ShapeGradient.RepeatSpread, ShapeGradient.ReflectSpread ]
            property variant spreadTexts: [ "PadSpread", "RepeatSpread", "ReflectSpread" ]
            property int spreadIdx: 0
            onTriggered: { spreadIdx = (spreadIdx + 1) % spreads.length; grad.spread = spreads[spreadIdx] }
        }


        Shape {
            anchors.fill: parent
            ShapePath {
                strokeColor: "gray"
                strokeWidth: 2
                fillColor: "transparent"
                PathMove { x: 0; y: 50 }
                PathLine { relativeX: 200; relativeY: 0 }
                PathMove { x: 0; y: 150 }
                PathLine { relativeX: 200; relativeY: 0 }
            }
        }
    }

    Text {
        anchors.right: parent.right
        text: spreadTimer.spreadTexts[spreadTimer.spreadIdx]
    }
}