examples/quick/tableview/pixelator/main.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

// Copyright (C) 2018 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick

import QtQuick.Window

import ImageModel

Window {
    visible: true
    width: 900
    height: 900
    title: qsTr("TableView Pixelator")

    //! [pixelcomponent]
    Component {
        id: pixelDelegate

        Item {
            required property real display

            readonly property real gray: display / 255.0
            readonly property real size: 16

            implicitWidth: size
            implicitHeight: size
            //! [pixelcomponent]

            //! [rectshape]
            Rectangle {
                id: rect
                anchors.centerIn: parent
                color: "#09102b"
                radius: parent.size - parent.gray * parent.size
                implicitWidth: radius
                implicitHeight: radius
                //! [rectshape]

                //! [animation]
                ColorAnimation on color {
                    id: colorAnimation
                    running: false
                    to: "#41cd52"
                    duration: 1500
                }
                //! [animation]
            }

            //! [interaction]
            MouseArea {
                anchors.fill: parent
                hoverEnabled: true
                onEntered: rect.color = "#cecfd5"
                onExited: colorAnimation.start()
            }
            //! [interaction]
        }
    }

    //! [tableview]
    TableView {
        id: tableView
        anchors.fill: parent
        model: ImageModel {
            source: ":/qt.png"
        }

        delegate: pixelDelegate
    }
    //! [tableview]
}