blob: a83d7c137b2394461ba41ee5d11c106f556b438f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
|
// Copyright (C) 2023 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
pragma ComponentBehavior: Bound
import QtQuick
import QtLocation
import QtPositioning
import WearableStyle
Item {
id: navigationPage
MapView {
id: view
anchors.fill: parent
map.plugin: Plugin {
name: "osm"
}
map.zoomLevel: 16
RouteModel {
id: routeModel
plugin : view.map.plugin
query: RouteQuery {
id: routeQuery
}
onStatusChanged: {
if (status == RouteModel.Ready) {
routeInfoModel.populate()
}
}
}
property real lat: 59.9485
property real lon: 10.7686
map.center: QtPositioning.coordinate(lat, lon)
Behavior on lon { PropertyAnimation { duration: 500; easing.type: Easing.InOutQuad } }
Behavior on lat { PropertyAnimation { duration: 500; easing.type: Easing.InOutQuad } }
MapItemView {
parent: view.map
model: routeModel
delegate: MapRoute {
id: route
required property var routeData
route: routeData
line.color: UIStyle.highlightColor
line.width: 5
smooth: true
opacity: 1
}
autoFitViewport: true
}
Component.onCompleted: {
var startCoordinate = QtPositioning.coordinate(59.9485, 10.7686);
var endCoordinate = QtPositioning.coordinate(59.9645, 10.671);
routeQuery.clearWaypoints();
routeQuery.addWaypoint(startCoordinate)
routeQuery.addWaypoint(endCoordinate)
routeQuery.travelModes = RouteQuery.CarTravel
routeQuery.routeOptimizations = RouteQuery.FastestRoute
routeModel.update();
}
}
ListModel {
id: routeInfoModel
function formatIconInstruction(direction)
{
switch (direction){
case RouteManeuver.NoDirection:
return "";
case RouteManeuver.DirectionForward:
return "forward";
case RouteManeuver.DirectionBearRight:
return "bearright";
case RouteManeuver.DirectionRight:
case RouteManeuver.DirectionHardRight:
return "right";
case RouteManeuver.DirectionLightRight:
return "lightright";
case RouteManeuver.DirectionUTurnRight:
return "uturnright";
case RouteManeuver.DirectionUTurnLeft:
return "uturleft";
case RouteManeuver.DirectionHardLeft:
case RouteManeuver.DirectionLeft:
return "left";
case RouteManeuver.DirectionLightLeft:
return "lightleft";
case RouteManeuver.DirectionBearLeft:
return "bearleft";
}
}
function formatShortInstruction(direction)
{
switch (direction){
case RouteManeuver.NoDirection:
return "";
case RouteManeuver.DirectionForward:
return "Move forward";
case RouteManeuver.DirectionBearRight:
return "Bear right";
case RouteManeuver.DirectionRight:
return "Turn right";
case RouteManeuver.DirectionHardRight:
return "Turn hard right";
case RouteManeuver.DirectionLightRight:
return "Turn slightly right";
case RouteManeuver.DirectionUTurnRight:
return "Uturn right";
case RouteManeuver.DirectionUTurnLeft:
return "Uturn left";
case RouteManeuver.DirectionHardLeft:
return "Turn hard left";
case RouteManeuver.DirectionLeft:
return "Turn left";
case RouteManeuver.DirectionLightLeft:
return "Turn slightly left";
case RouteManeuver.DirectionBearLeft:
return "Bear left";
}
}
function formatTime(sec)
{
var value = sec
var seconds = value % 60
value /= 60
value = (value > 1) ? Math.round(value) : 0
var minutes = value % 60
value /= 60
value = (value > 1) ? Math.round(value) : 0
var hours = value
if (hours > 0) value = hours + "h:"+ minutes + "m"
else value = minutes + "min"
return value
}
function formatDistance(meters)
{
var dist = Math.round(meters)
if (dist > 1000 ){
if (dist > 100000){
dist = Math.round(dist / 1000)
}
else{
dist = Math.round(dist / 100)
dist = dist / 10
}
dist = dist + " km"
}
else{
dist = dist + " m"
}
return dist
}
function populate()
{
routeInfoModel.clear()
if (routeModel.count > 0) {
for (var i = 0; i < routeModel.get(0).segments.length; i++) {
routeInfoModel.append({
"icon": formatIconInstruction(routeModel.get(0).segments[i].maneuver.direction),
"shortInfo": formatShortInstruction(routeModel.get(0).segments[i].maneuver.direction),
"instruction": routeModel.get(0).segments[i].maneuver.instructionText,
"distance": qsTr("in") + " " + formatDistance(routeModel.get(0).segments[i].maneuver.distanceToNextInstruction)
});
}
}
}
}
ListView {
id: routeView
height: 90
anchors.bottom: navigationPage.bottom
anchors.left: navigationPage.left
anchors.right: navigationPage.right
anchors.rightMargin: 10
anchors.leftMargin: 15
anchors.bottomMargin: 20
spacing: 12
clip: true
focus: true
boundsBehavior: Flickable.StopAtBounds
snapMode: ListView.SnapToItem
property int centeredIndex: 0
model: routeInfoModel
delegate: RouteElement {
width: routeView.width - 10
height: routeView.height - 10
}
onContentYChanged: {
centeredIndex = indexAt(10, contentY)
if (centeredIndex > -1) {
view.lat = routeModel.get(0).segments[centeredIndex].maneuver.position.latitude
view.lon = routeModel.get(0).segments[centeredIndex].maneuver.position.longitude
}
}
}
function incrementPoint() {
routeView.centeredIndex++
if (routeView.centeredIndex >= routeInfoModel.count)
routeView.centeredIndex = 0
routeView.positionViewAtIndex(routeView.centeredIndex, ListView.Center)
}
}
|
