blob: e833a92da16eb1b4bc5248fc5d685946e2e2a01b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
// Copyright (C) 2017 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
import QtQuick
import QtQuick.Templates as T
import QtQuick.Controls.Imagine
import QtQuick.Controls.Imagine.impl
T.GroupBox {
id: control
implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
contentWidth + leftPadding + rightPadding,
implicitLabelWidth + leftPadding + rightPadding)
implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
contentHeight + topPadding + bottomPadding)
topPadding: ((background as NinePatchImage)?.topPadding ?? 0) + (implicitLabelWidth > 0 ? implicitLabelHeight + spacing : 0)
leftPadding: ((background as NinePatchImage)?.leftPadding ?? 0)
rightPadding: ((background as NinePatchImage)?.rightPadding ?? 0)
bottomPadding: ((background as NinePatchImage)?.bottomPadding ?? 0)
label: Label {
width: control.width
topPadding: background.topPadding
leftPadding: background.leftPadding
rightPadding: background.rightPadding
bottomPadding: background.bottomPadding
text: control.title
elide: Text.ElideRight
verticalAlignment: Text.AlignVCenter
color: control.palette.windowText
background: NinePatchImage {
width: parent.width
height: parent.height
source: Imagine.url + "groupbox-title"
NinePatchImageSelector on source {
states: [
{"disabled": !control.enabled},
{"mirrored": control.mirrored}
]
}
}
}
background: NinePatchImage {
x: -leftInset
y: control.topPadding - control.bottomPadding - topInset
width: control.width + leftInset + rightInset
height: control.height + topInset + bottomInset - control.topPadding + control.bottomPadding
source: Imagine.url + "groupbox-background"
NinePatchImageSelector on source {
states: [
{"disabled": !control.enabled},
{"mirrored": control.mirrored}
]
}
}
}
|