blob: 7547d3d04f942b01b331398e10f7d1897e9c88e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
// Copyright (C) 2022 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
import QtQuick
import QtQuick.Templates as T
import QtQuick.Controls.impl
import QtQuick.Controls.Material
import QtQuick.Controls.Material.impl
T.RangeSlider {
id: control
implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
first.implicitHandleWidth + leftPadding + rightPadding,
second.implicitHandleWidth + leftPadding + rightPadding)
implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
first.implicitHandleHeight + topPadding + bottomPadding,
second.implicitHandleHeight + topPadding + bottomPadding)
padding: 6
// The RangeSlider is discrete if all of the following requirements are met:
// * stepSize is positive
// * snapMode is set to SnapAlways
// * the difference between to and from is cleanly divisible by the stepSize
// * the number of tick marks intended to be rendered is less than the width to height ratio, or vice versa for vertical sliders.
readonly property real __steps: Math.abs(to - from) / stepSize
readonly property bool __isDiscrete: stepSize >= Number.EPSILON
&& snapMode === Slider.SnapAlways
&& Math.abs(Math.round(__steps) - __steps) < Number.EPSILON
&& Math.floor(__steps) < (horizontal ? background.width / background.height : background.height / background.width)
first.handle: SliderHandle {
x: control.leftPadding + (control.horizontal ? control.first.visualPosition * (control.availableWidth - width) : (control.availableWidth - width) / 2)
y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : control.first.visualPosition * (control.availableHeight - height))
value: control.first.value
handleHasFocus: activeFocus
handlePressed: control.first.pressed
handleHovered: control.first.hovered
}
second.handle: SliderHandle {
x: control.leftPadding + (control.horizontal ? control.second.visualPosition * (control.availableWidth - width) : (control.availableWidth - width) / 2)
y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : control.second.visualPosition * (control.availableHeight - height))
value: control.second.value
handleHasFocus: activeFocus
handlePressed: control.second.pressed
handleHovered: control.second.hovered
}
background: Item {
x: control.leftPadding + (control.horizontal ? 0 : (control.availableWidth - width) / 2)
y: control.topPadding + (control.horizontal ? (control.availableHeight - height) / 2 : 0)
implicitWidth: control.horizontal ? 200 : 48
implicitHeight: control.horizontal ? 48 : 200
width: control.horizontal ? control.availableWidth : 4
height: control.horizontal ? 4 : control.availableHeight
Rectangle {
x: (control.horizontal ? (control.first.implicitHandleWidth / 2) - (control.__isDiscrete ? 2 : 0) : 0)
y: (control.horizontal ? 0 : (control.first.implicitHandleHeight / 2) - (control.__isDiscrete ? 2 : 0))
width: parent.width - (control.horizontal ? (control.first.implicitHandleWidth - (control.__isDiscrete ? 4 : 0)) : 0)
height: parent.height - (control.horizontal ? 0 : (control.first.implicitHandleHeight - (control.__isDiscrete ? 4 : 0)))
scale: control.horizontal && control.mirrored ? -1 : 1
radius: Math.min(width, height) / 2
color: control.enabled ? Color.transparent(control.Material.accentColor, 0.33) : control.Material.sliderDisabledColor
Rectangle {
x: control.horizontal ? control.first.position * parent.width : 0
y: control.horizontal ? 0 : control.second.visualPosition * parent.height
width: control.horizontal ? control.second.position * parent.width - control.first.position * parent.width : 4
height: control.horizontal ? 4 : control.second.position * parent.height - control.first.position * parent.height
radius: Math.min(width, height) / 2
color: control.enabled ? control.Material.accentColor : control.Material.sliderDisabledColor
}
// Declaring this as a property (in combination with the parent binding below) avoids ids,
// which prevent deferred execution.
property Repeater repeater: Repeater {
parent: control.background.children[0]
model: control.__isDiscrete ? Math.floor(control.__steps) + 1 : 0
delegate: Rectangle {
width: 2
height: 2
radius: 2
x: control.horizontal ? (parent.width - width * 2) * currentPosition + (width / 2) : (parent.width - width) / 2
y: control.horizontal ? (parent.height - height) / 2 : (parent.height - height * 2) * currentPosition + (height / 2)
color: (control.horizontal && control.first.visualPosition < currentPosition && control.second.visualPosition > currentPosition)
|| (!control.horizontal && control.first.visualPosition > currentPosition && control.second.visualPosition < currentPosition)
? control.Material.primaryHighlightedTextColor : control.Material.accentColor
required property int index
readonly property real currentPosition: index / (parent.repeater.count - 1)
}
}
}
}
}
|
