blob: 9294146facfdb270b0eba95b36222d1894e0f9b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
// Copyright (C) 2017 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
import QtQuick
import QtQuick.Templates as T
import QtQuick.Controls.impl
import QtQuick.Controls.Material
import QtQuick.Controls.Material.impl
T.TextField {
id: control
implicitWidth: implicitBackgroundWidth + leftInset + rightInset
|| Math.max(contentWidth, placeholder.implicitWidth) + leftPadding + rightPadding
implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
contentHeight + topPadding + bottomPadding)
// If we're clipped, set topInset to half the height of the placeholder text to avoid it being clipped.
topInset: clip ? placeholder.largestHeight / 2 : 0
leftPadding: Material.textFieldHorizontalPadding
rightPadding: Material.textFieldHorizontalPadding
// Need to account for the placeholder text when it's sitting on top.
topPadding: Material.containerStyle === Material.Filled
? placeholderText.length > 0 && (activeFocus || length > 0)
? Material.textFieldVerticalPadding + placeholder.largestHeight
: Material.textFieldVerticalPadding
// Account for any topInset (used to avoid floating placeholder text being clipped),
// otherwise the text will be too close to the background.
: Material.textFieldVerticalPadding + topInset
bottomPadding: Material.textFieldVerticalPadding
color: enabled ? Material.foreground : Material.hintTextColor
selectionColor: Material.accentColor
selectedTextColor: Material.primaryHighlightedTextColor
placeholderTextColor: enabled && activeFocus ? Material.accentColor : Material.hintTextColor
verticalAlignment: TextInput.AlignVCenter
Material.containerStyle: Material.Outlined
cursorDelegate: CursorDelegate { }
FloatingPlaceholderText {
id: placeholder
// Don't set this to control.leftPadding, because we don't want it to change if the user changes leftPadding.
x: control.Material.textFieldHorizontalPadding
width: control.width - (control.leftPadding + control.rightPadding)
text: control.placeholderText
font: control.font
color: control.placeholderTextColor
elide: Text.ElideRight
renderType: control.renderType
filled: control.Material.containerStyle === Material.Filled
verticalPadding: control.Material.textFieldVerticalPadding
controlHasActiveFocus: control.activeFocus
controlHasText: control.length > 0
controlImplicitBackgroundHeight: control.implicitBackgroundHeight
controlHeight: control.height
}
background: MaterialTextContainer {
implicitWidth: 120
implicitHeight: control.Material.textFieldHeight
filled: control.Material.containerStyle === Material.Filled
fillColor: control.Material.textFieldFilledContainerColor
outlineColor: (enabled && control.hovered) ? control.Material.primaryTextColor : control.Material.hintTextColor
focusedOutlineColor: control.Material.accentColor
// When the control's size is set larger than its implicit size, use whatever size is smaller
// so that the gap isn't too big.
placeholderTextWidth: Math.min(placeholder.width, placeholder.implicitWidth) * placeholder.scale
placeholderTextHAlign: control.effectiveHorizontalAlignment
controlHasActiveFocus: control.activeFocus
controlHasText: control.length > 0
placeholderHasText: placeholder.text.length > 0
horizontalPadding: control.Material.textFieldHorizontalPadding
}
}
|
