blob: ca30a7fe99fd19a6dffd5530074b195e3e511c39 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
|
// Copyright (C) 2020 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only
import QtQuick 2.15
Rectangle {
id: root
width: 640
height: 480
color: "#444"
component CheckBox: Row {
id: cbRoot
property bool checked : true
property string label : "CheckBox"
spacing: 4
Rectangle {
width: 16; height: 16
// comment out this color change to test whether we rely on "dirty" items to
// trigger QQuickDeliveryAgentPrivate::flushFrameSynchronousEvents() to update hover state
color: cbRoot.checked ? "cadetblue" : "transparent"
border.color: "black"
TapHandler { onTapped: cbRoot.checked = !cbRoot.checked }
}
Text { text: cbRoot.label }
}
component ButtonsAndStuff: Column {
anchors.fill: parent
anchors.margins: 8
spacing: 8
function toggleMAEnabled() { maButtonCB.checked = !maButtonCB.checked }
function toggleMAHover() { maButtonHoverCB.checked = !maButtonHoverCB.checked }
function toggleHHEnabled() { hhButtonHoverCB.checked = !hhButtonHoverCB.checked }
CheckBox {
id: maButtonCB
label: "enabled"
}
CheckBox {
id: maButtonHoverCB
label: "hover enabled"
}
Rectangle {
objectName: "buttonWithMA"
width: parent.width
height: 30
color: buttonMA.pressed ? "lightsteelblue" : "#999"
border.color: buttonMA.containsMouse ? "cyan" : "transparent"
MouseArea {
id: buttonMA
objectName: "buttonMA"
enabled: maButtonCB.checked
hoverEnabled: maButtonHoverCB.checked
cursorShape: Qt.UpArrowCursor
anchors.fill: parent
}
Text {
anchors.centerIn: parent
text: "MouseArea"
}
}
CheckBox {
id: hhButtonHoverCB
label: "hover enabled"
}
Rectangle {
id: buttonRoot
objectName: "buttonWithHH"
width: parent.width
height: 30
color: flash ? "#999" : "white"
border.color: buttonHH.hovered ? "cyan" : "transparent"
property bool flash: true
HoverHandler {
id: buttonHH
objectName: "buttonHH"
acceptedDevices: PointerDevice.AllDevices
enabled: hhButtonHoverCB.checked
cursorShape: tapHandler.pressed ? Qt.BusyCursor : Qt.PointingHandCursor
}
TapHandler {
id: tapHandler
onTapped: {
console.log("buttonRoot tapped")
buttonHH.enabled = !buttonHH.enabled
}
}
Text {
anchors.centerIn: parent
text: "HoverHandler"
}
}
}
Rectangle {
id: paddle
objectName: "paddle"
width: 100
height: 100
color: paddleHH.hovered ? "indianred" : "#888"
x: (parent.width - width) / 2
y: parent.height - 100
radius: 10
HoverHandler {
id: paddleHH
objectName: "paddleHH"
}
}
Rectangle {
objectName: "topSidebar"
radius: 5
antialiasing: true
x: -radius
y: -radius
width: 120
height: 200
border.color: topSidebarHH.hovered ? "cyan" : "black"
color: "#777"
Rectangle {
color: "cyan"
width: 10
height: width
radius: width / 2
visible: topSidebarHH.hovered
x: topSidebarHH.point.position.x - width / 2
y: topSidebarHH.point.position.y - height / 2
z: 100
}
HoverHandler {
id: topSidebarHH
objectName: "topSidebarHH"
cursorShape: Qt.OpenHandCursor
}
ButtonsAndStuff {
id: tbs
objectName: "topSidebarContents"
anchors.fill: parent
Shortcut {
sequence: "Ctrl+E"
onActivated: tbs.toggleMAEnabled()
}
Shortcut {
sequence: "Ctrl+M"
onActivated: tbs.toggleMAHover()
}
Shortcut {
sequence: "Ctrl+H"
onActivated: tbs.toggleHHEnabled()
}
}
}
Rectangle {
objectName: "bottomSidebar"
radius: 5
antialiasing: true
x: -radius
anchors.bottom: parent.bottom
anchors.bottomMargin: -radius
width: 120
height: 200
border.color: bottomSidebarMA.containsMouse ? "cyan" : "black"
color: "#777"
MouseArea {
id: bottomSidebarMA
objectName: "bottomSidebarMA"
hoverEnabled: true
cursorShape: Qt.ClosedHandCursor
anchors.fill: parent
}
ButtonsAndStuff {
objectName: "bottomSidebarContents"
anchors.fill: parent
}
}
}
|
