blob: 9bf5d5875ad67ef5cbc6b1b9a1eb756d99379417 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
// Copyright (C) 2017 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0
import QtQuick 2.12
import QtQuick.Dialogs 1.0
import Qt.labs.folderlistmodel 1.0
import "content"
Rectangle {
id: root
visible: true
width: 1024; height: 600
color: "black"
property int highestZ: 0
property real defaultSize: 200
property real surfaceViewportRatio: 1.5
FileDialog {
id: fileDialog
title: "Choose a folder with some images"
selectFolder: true
onAccepted: folderModel.folder = fileUrl + "/"
}
Shortcut {
id: openShortcut
sequence: StandardKey.Open
onActivated: fileDialog.open()
}
FakeFlickable {
id: flick
anchors.fill: parent
contentWidth: width * 2
contentHeight: height * 2
Repeater {
model: FolderListModel {
id: folderModel
folder: "resources/"
objectName: "folderModel"
showDirs: false
nameFilters: ["*.png", "*.jpg", "*.gif"]
}
Rectangle {
id: photoFrame
objectName: "frame-" + fileName
width: image.width * (1 + 0.10 * image.height / image.width)
height: image.height * 1.10
scale: defaultSize / Math.max(image.sourceSize.width, image.sourceSize.height)
Behavior on scale { NumberAnimation { duration: 200 } }
Behavior on x { NumberAnimation { duration: 200 } }
Behavior on y { NumberAnimation { duration: 200 } }
border.color: pinchHandler.active || dragHandler.active ? "red" : "black"
border.width: 2
smooth: true
antialiasing: true
Component.onCompleted: {
x = Math.random() * root.width - width / 2
y = Math.random() * root.height - height / 2
rotation = Math.random() * 13 - 6
}
Image {
id: image
anchors.centerIn: parent
fillMode: Image.PreserveAspectFit
source: folderModel.folder + fileName
antialiasing: true
}
MomentumAnimation { id: anim; target: photoFrame }
DragHandler {
id: dragHandler
onActiveChanged: {
if (!active)
anim.restart(point.velocity)
}
}
PinchHandler {
id: pinchHandler
minimumRotation: -360
maximumRotation: 360
minimumScale: 0.1
maximumScale: 10
property real zRestore: 0
}
}
}
}
Rectangle {
id: verticalScrollDecorator
anchors.right: parent.right
anchors.margins: 2
color: "cyan"
border.color: "black"
border.width: 1
width: 5
radius: 2
antialiasing: true
height: flick.height * (flick.height / flick.contentHeight) - (width - anchors.margins) * 2
y: -flick.contentY * (flick.height / flick.contentHeight)
NumberAnimation on opacity { id: vfade; to: 0; duration: 500 }
onYChanged: { opacity = 1.0; fadeTimer.restart() }
}
Rectangle {
id: horizontalScrollDecorator
anchors.bottom: parent.bottom
anchors.margins: 2
color: "cyan"
border.color: "black"
border.width: 1
height: 5
radius: 2
antialiasing: true
width: flick.width * (flick.width / flick.contentWidth) - (height - anchors.margins) * 2
x: -flick.contentX * (flick.width / flick.contentWidth)
NumberAnimation on opacity { id: hfade; to: 0; duration: 500 }
onXChanged: { opacity = 1.0; fadeTimer.restart() }
}
Timer { id: fadeTimer; interval: 1000; onTriggered: { hfade.start(); vfade.start() } }
Text {
anchors.bottom: parent.bottom
anchors.left: parent.left
anchors.right: parent.right
anchors.margins: 10
color: "darkgrey"
wrapMode: Text.WordWrap
font.pointSize: 8
text: "Press " + openShortcut.nativeText + " to choose a different image folder\n" +
"On a touchscreen: use two fingers to zoom and rotate, one finger to drag\n" +
"With a mouse: drag normally"
}
}
|