blob: fed5d708a8ce62a2f8fd7d5f74a82a9ed598fedf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
QT += core
FLEX += $$PWD/qiviqueryparser.l
QLALR += $$PWD/qiviqueryparser.g
enable-qlalr {
build-pass: message("Using flex and qlalr to generate code")
flex.output = $$PWD/${QMAKE_FILE_BASE}_flex_p.h
flex.commands = flex -L --nounistd -o ${QMAKE_FILE_OUT} ${QMAKE_FILE_NAME}
flex.dependency_type = TYPE_C
flex.input = FLEX
flex.CONFIG += no_link
QMAKE_EXTRA_COMPILERS += flex
qlalr.output = $$PWD/${QMAKE_FILE_BASE}_p.h
qlalr.commands = cd $$PWD; $$[QT_INSTALL_BINS]/qlalr --qt --no-debug --no-lines --verbose ${QMAKE_FILE_NAME}
qlalr.dependency_type = TYPE_C
qlalr.input = QLALR
qlalr.CONFIG += no_link
QMAKE_EXTRA_COMPILERS += qlalr
} else {
HEADERS += $$PWD/qiviqueryparser_p.h \
$$PWD/qiviqueryparser_flex_p.h
OTHER_FILES += $$FLEX
OTHER_FILES += $$QLALR
}
HEADERS += \
$$PWD/qiviqueryterm.h \
$$PWD/qiviqueryterm_p.h
SOURCES += \
$$PWD/qiviqueryterm.cpp
|
