1 files changed, 27 insertions, 0 deletions
diff --git a/src/multimedia/shaders/uyvy.frag b/src/multimedia/shaders/uyvy.frag
new file mode 100644
index 000000000..26a83da3f
--- /dev/null
+++ b/src/multimedia/shaders/uyvy.frag
@@ -0,0 +1,27 @@
+#version 440
+#extension GL_GOOGLE_include_directive : enable
+
+#include "uniformbuffer.glsl"
+#include "colortransfer.glsl"
+
+layout(location = 0) in vec2 texCoord;
+layout(location = 0) out vec4 fragColor;
+
+layout(binding = 1) uniform sampler2D plane1Texture;
+
+void main()
+{
+    int x = int(floor(texCoord.x * ubuf.width));
+    bool rightSubPixel = (x/2*2 != x);
+    float Y = rightSubPixel ? texture(plane1Texture, texCoord).a : texture(plane1Texture, texCoord).g;
+    vec2 UV = texture(plane1Texture, texCoord).rb;
+    fragColor = ubuf.colorMatrix * vec4(Y, UV, 1.0) * ubuf.opacity;
+
+#ifdef QMM_OUTPUTSURFACE_LINEAR
+    fragColor = convertSRGBToLinear(fragColor);
+#endif
+
+    // Clamp output to valid range to account for out-of-range
+    // input values and numerical inaccuracies in YUV->RGB conversion
+    fragColor = clamp(fragColor, 0.0, 1.0);
+}