blob: 744b37268c0b211a86e77776eff02f223e2a9951 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright (C) 2022 The Qt Company Ltd.
# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0
find_package(PkgConfig QUIET)
function(find_component component prefix header library)
if(NOT TARGET VAAPI::${component})
string(TOUPPER ${component} upper)
pkg_check_modules(PC_VAAPI_${upper} ${prefix} IMPORTED_TARGET)
if(TARGET PkgConfig::PC_VAAPI_${upper})
add_library(VAAPI::${component} INTERFACE IMPORTED)
target_link_libraries(VAAPI::${component} INTERFACE PkgConfig::PC_VAAPI_${upper})
else()
find_path(VAAPI_${component}_INCLUDE_DIR
NAMES ${header}
PATH_SUFFIXES VAAPI-1.0
)
find_library(VAAPI_${component}_LIBRARY
NAMES ${library}
)
if(VAAPI_${component}_LIBRARY AND VAAPI_${component}_INCLUDE_DIR)
add_library(VAAPI::${component} INTERFACE IMPORTED)
target_include_directories(VAAPI::${component} INTERFACE ${VAAPI_${component}_INCLUDE_DIR})
target_link_libraries(VAAPI::${component} INTERFACE ${VAAPI_${component}_LIBRARY})
endif()
mark_as_advanced(VAAPI_${component}_INCLUDE_DIR VAAPI_${component}_LIBRARY)
endif()
endif()
if(TARGET VAAPI::${component})
set(VAAPI_${component}_FOUND TRUE PARENT_SCOPE)
endif()
endfunction()
find_component(VA libva va/va.h libva)
find_component(DRM libva-drm va/va-drm.h libva-drm)
if(TARGET VAAPI::VA)
target_link_libraries(VAAPI::VA)
endif()
if(TARGET VAAPI::VA AND TARGET VAAPI::DRM)
target_link_libraries(VAAPI::DRM INTERFACE VAAPI::VA)
endif()
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(VAAPI
REQUIRED_VARS
VAAPI_VA_FOUND
VAAPI_DRM_FOUND
HANDLE_COMPONENTS
)
if(VAAPI_FOUND AND NOT TARGET VAAPI::VAAPI)
add_library(VAAPI::VAAPI INTERFACE IMPORTED)
target_link_libraries(VAAPI::VAAPI INTERFACE
VAAPI::VA
VAAPI::DRM
)
endif()
|
