Add qmlplugindump tool to qtquick1 module

Change-Id: I94a52b2207fb2b5dd66e9e4da8f42ddf2daf4da0
Reviewed-by: Andrew den Exter <andrew.den-exter@nokia.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/tools/qmlplugindump/qmlplugindump.pro b/tools/qmlplugindump/qmlplugindump.pro
new file mode 100644
index 00000000..e8b5fac0
--- /dev/null
+++ b/tools/qmlplugindump/qmlplugindump.pro
@@ -0,0 +1,38 @@
+TEMPLATE = app
+CONFIG += qt uic console
+DESTDIR = $$QT.declarative.bins
+
+QT += quick1 quick1-private core-private
+!isEmpty(QT.widgets.name): QT += gui gui-private widgets widgets-private
+
+TARGET = qmlplugindump
+
+SOURCES += \
+    main.cpp \
+    qmlstreamwriter.cpp
+
+HEADERS += \
+    qmlstreamwriter.h
+
+OTHER_FILES += Info.plist
+macx: QMAKE_INFO_PLIST = Info.plist
+
+# Build debug and release versions of the tool on Windows -
+# if debug and release versions of Qt have been built.
+!build_pass:win32 {
+    CONFIG -= debug release debug_and_release build_all
+
+    contains(QT_CONFIG,debug):contains(QT_CONFIG,release) {
+        CONFIG += debug_and_release build_all
+    } else {
+        contains(QT_CONFIG,debug): CONFIG += debug
+        contains(QT_CONFIG,release): CONFIG += release
+    }
+}
+
+CONFIG(debug, debug|release) {
+    win32: TARGET = $$join(TARGET,,,d)
+}
+
+target.path = $$[QT_INSTALL_BINS]
+INSTALLS += target