SwipeDelegate: add doc example

Change-Id: I3fb5434722dd5d6cd744e3d853a5a15e52bf03d0
Task-number: QTBUG-54645
Reviewed-by: J-P Nurmi <jpnurmi@qt.io>

1 files changed, 82 insertions, 0 deletions

diff --git a/src/imports/controls/doc/snippets/qtquickcontrols2-swipedelegate.qml b/src/imports/controls/doc/snippets/qtquickcontrols2-swipedelegate.qml
new file mode 100644
index 00000000..36c96190
--- /dev/null
+++ b/src/imports/controls/doc/snippets/qtquickcontrols2-swipedelegate.qml
@@ -0,0 +1,82 @@
+/****************************************************************************
+**
+** Copyright (C) 2016 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the documentation of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:FDL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Free Documentation License Usage
+** Alternatively, this file may be used under the terms of the GNU Free
+** Documentation License version 1.3 as published by the Free Software
+** Foundation and appearing in the file included in the packaging of
+** this file. Please review the following information to ensure
+** the GNU Free Documentation License version 1.3 requirements
+** will be met: http://www.gnu.org/copyleft/fdl.html.
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.8
+import QtQuick.Controls 2.1
+
+//! [file]
+ListView {
+    id: listView
+    anchors.fill: parent
+    model: ListModel {
+        ListElement { sender: "Bob Bobbleton"; title: "How are you going?" }
+        ListElement { sender: "Rug Emporium"; title: "SALE! All rugs MUST go!" }
+        ListElement { sender: "Electric Co."; title: "Electricity bill 15/07/2016 overdue" }
+        ListElement { sender: "Tips"; title: "Five ways this tip will save your life" }
+    }
+    delegate: SwipeDelegate {
+        id: swipeDelegate
+        text: model.sender + " - " + model.title
+        width: parent.width
+
+        ListView.onRemove: SequentialAnimation {
+            PropertyAction {
+                target: swipeDelegate
+                property: "ListView.delayRemove"
+                value: true
+            }
+            NumberAnimation {
+                target: swipeDelegate
+                property: "height"
+                to: 0
+                easing.type: Easing.InOutQuad
+            }
+            PropertyAction {
+                target: swipeDelegate;
+                property: "ListView.delayRemove";
+                value: false
+            }
+        }
+
+        swipe.right: Label {
+            id: deleteLabel
+            text: qsTr("Delete")
+            color: "white"
+            verticalAlignment: Label.AlignVCenter
+            padding: 12
+            height: parent.height
+            anchors.right: parent.right
+
+            SwipeDelegate.onClicked: listView.model.remove(index)
+
+            background: Rectangle {
+                color: deleteLabel.SwipeDelegate.pressed ? Qt.darker("tomato", 1.1) : "tomato"
+            }
+        }
+    }
+}
+//! [file]