Add Universal style

https://dev.windows.com/design

Change-Id: I1d8c633ae246724649a6ed71b300a56ba9572405
Reviewed-by: Mitch Curtis <mitch.curtis@theqtcompany.com>

1 files changed, 149 insertions, 0 deletions

diff --git a/src/imports/controls/universal/SpinBox.qml b/src/imports/controls/universal/SpinBox.qml
new file mode 100644
index 00000000..75298895
--- /dev/null
+++ b/src/imports/controls/universal/SpinBox.qml
@@ -0,0 +1,149 @@
+/****************************************************************************
+**
+** Copyright (C) 2015 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the Qt Labs Controls module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL3$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPLv3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or later as published by the Free
+** Software Foundation and appearing in the file LICENSE.GPL included in
+** the packaging of this file. Please review the following information to
+** ensure the GNU General Public License version 2.0 requirements will be
+** met: http://www.gnu.org/licenses/gpl-2.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.6
+import Qt.labs.templates 1.0 as T
+import Qt.labs.controls.universal 1.0
+
+T.SpinBox {
+    id: control
+
+    implicitWidth: Math.max(background ? background.implicitWidth : 0,
+                            contentItem.implicitWidth + 16 +
+                            (up.indicator ? up.indicator.implicitWidth : 0) +
+                            (down.indicator ? down.indicator.implicitWidth : 0))
+    implicitHeight: Math.max(contentItem.implicitHeight + topPadding + bottomPadding,
+                             background ? background.implicitHeight : 0,
+                             up.indicator ? up.indicator.implicitHeight : 0,
+                             down.indicator ? down.indicator.implicitHeight : 0)
+
+    // TextControlThemePadding + 2 (border)
+    topPadding: 5
+    bottomPadding: 7
+    leftPadding: 12 + (control.mirrored ? (up.indicator ? up.indicator.width : 0) : (down.indicator ? down.indicator.width : 0))
+    rightPadding: 8 + (control.mirrored ? (down.indicator ? down.indicator.width : 0) : (up.indicator ? up.indicator.width : 0))
+
+    Universal.theme: activeFocus ? Universal.Light : undefined
+
+    font.pixelSize: Universal.fontSize
+    font.family: Universal.fontFamily
+
+    //! [validator]
+    validator: IntValidator {
+        locale: control.locale.name
+        bottom: Math.min(control.from, control.to)
+        top: Math.max(control.from, control.to)
+    }
+    //! [validator]
+
+    //! [contentItem]
+    contentItem: TextInput {
+        text: control.textFromValue(control.value, control.locale)
+
+        font: control.font
+        color: !enabled ? control.Universal.chromeDisabledLowColor :
+                activeFocus ? control.Universal.chromeBlackHighColor : control.Universal.baseHighColor
+        selectionColor: control.Universal.accentColor
+        selectedTextColor: control.Universal.chromeWhiteColor
+        horizontalAlignment: Qt.AlignHCenter
+        verticalAlignment: TextInput.AlignVCenter
+        renderType: Text.NativeRendering
+
+        validator: control.validator
+        inputMethodHints: Qt.ImhFormattedNumbersOnly
+    }
+    //! [contentItem]
+
+    //! [up.indicator]
+    up.indicator: Item {
+        implicitWidth: 26
+        height: parent.height
+        x: control.mirrored ? 0 : parent.width - width
+
+        Rectangle {
+            x: 2; y: 2
+            width: parent.width - 4
+            height: parent.height - 4
+            color: !control.up.pressed ? "transparent" :
+                   control.activeFocus ? control.Universal.accentColor
+                                       : control.Universal.chromeDisabledLowColor
+        }
+
+        Image {
+            x: (parent.width - width) / 2
+            y: (parent.height - height) / 2
+            source: "image://universal/rightarrow/" + (!control.enabled ? control.Universal.chromeDisabledLowColor :
+                                                                          control.activeFocus ? control.Universal.chromeBlackHighColor : control.Universal.baseHighColor)
+        }
+    }
+    //! [up.indicator]
+
+    //! [down.indicator]
+    down.indicator: Item {
+        implicitWidth: 26
+        height: parent.height
+        x: control.mirrored ? parent.width - width : 0
+
+        Rectangle {
+            x: 2; y: 2
+            width: parent.width - 4
+            height: parent.height - 4
+            color: !control.down.pressed ? "transparent" :
+                     control.activeFocus ? control.Universal.accentColor
+                                         : control.Universal.chromeDisabledLowColor
+        }
+
+        Image {
+            x: (parent.width - width) / 2
+            y: (parent.height - height) / 2
+            source: "image://universal/leftarrow/" + (!control.enabled ? control.Universal.chromeDisabledLowColor :
+                                                                         control.activeFocus ? control.Universal.chromeBlackHighColor : control.Universal.baseHighColor)
+        }
+    }
+    //! [down.indicator]
+
+    //! [background]
+    background: Rectangle {
+        implicitWidth: 60 + 26 // TextControlThemeMinWidth - 4 (border)
+        implicitHeight: 28 // TextControlThemeMinHeight - 4 (border)
+
+        border.width: 2 // TextControlBorderThemeThickness
+        border.color: !control.enabled ? control.Universal.baseLowColor :
+                       control.activeFocus ? control.Universal.accentColor : control.Universal.chromeDisabledLowColor
+        color: control.enabled ? control.Universal.altHighColor : control.Universal.baseLowColor
+    }
+    //! [background]
+}