Register C++ types declaratively

Adapt to the new way of registering C++ types. The types need to be
seen at compile time so that code can be generated that invokes them.

This patch:

- Adds QML_* macros where applicable.
- Adapts the build system files to the new way of registering modules.
- Splits up the QtQuick.Controls[.*].impl files into their own plugins,
  as we can only register one QML module per .pro file.
- Removes C++ type registration calls in every plugin.
- Moves private types from src/quickcontrols2/quickcontrols2.pro
  to src/quickcontrols2/impl/quickcontrols2-impl.pro. Some of these
  types need to be exposed to QML, but quickcontrols2.pro is already in
  use to declare the QtQuick.Controls import (and also provides the
  public C++ QQuickStyle API), and the new QML_IMPORT_NAME/VERSION
  syntax only allows one module per project. As some of the types that
  need to be exposed to QML are also referenced by some C++ code (e.g.
  tests, etc.), we just move all of the private types to the new
  library.

Follow-up patches will register the QML types declaratively.

Task-number: QTBUG-82922
Change-Id: Iaf9ee106237d61701d57a8896f3822304c8151a6
Reviewed-by: Ulf Hermann <ulf.hermann@qt.io>

1 files changed, 54 insertions, 0 deletions

diff --git a/src/quickcontrols2impl/quickcontrols2impl.pro b/src/quickcontrols2impl/quickcontrols2impl.pro
new file mode 100644
index 00000000..7a7d2862
--- /dev/null
+++ b/src/quickcontrols2impl/quickcontrols2impl.pro
@@ -0,0 +1,54 @@
+TARGET = QtQuickControls2Impl
+MODULE = quickcontrols2impl
+
+QT += quick
+QT_PRIVATE += core-private gui-private qml-private quick-private quicktemplates2-private
+
+DEFINES += QT_NO_CAST_TO_ASCII QT_NO_CAST_FROM_ASCII
+
+HEADERS += \
+    $$PWD/qtquickcontrols2implglobal_p.h \
+    $$PWD/qquickanimatednode_p.h \
+    $$PWD/qquickattachedobject_p.h \
+    $$PWD/qquickchecklabel_p.h \
+    $$PWD/qquickclippedtext_p.h \
+    $$PWD/qquickcolor_p.h \
+    $$PWD/qquickcolorimage_p.h \
+    $$PWD/qquickiconimage_p.h \
+    $$PWD/qquickiconimage_p_p.h \
+    $$PWD/qquickiconlabel_p.h \
+    $$PWD/qquickiconlabel_p_p.h \
+    $$PWD/qquickitemgroup_p.h \
+    $$PWD/qquickmnemoniclabel_p.h \
+    $$PWD/qquickpaddedrectangle_p.h \
+    $$PWD/qquickplaceholdertext_p.h \
+    $$PWD/qtquickcontrols2foreign_p.h
+
+SOURCES += \
+    $$PWD/qquickanimatednode.cpp \
+    $$PWD/qquickattachedobject.cpp \
+    $$PWD/qquickchecklabel.cpp \
+    $$PWD/qquickclippedtext.cpp \
+    $$PWD/qquickcolor.cpp \
+    $$PWD/qquickcolorimage.cpp \
+    $$PWD/qquickiconimage.cpp \
+    $$PWD/qquickiconlabel.cpp \
+    $$PWD/qquickitemgroup.cpp \
+    $$PWD/qquickmnemoniclabel.cpp \
+    $$PWD/qquickpaddedrectangle.cpp \
+    $$PWD/qquickplaceholdertext.cpp
+
+qtConfig(quick-listview):qtConfig(quick-pathview) {
+    HEADERS += \
+        $$PWD/qquicktumblerview_p.h
+    SOURCES += \
+        $$PWD/qquicktumblerview.cpp
+}
+
+QMLTYPES_FILENAME = plugins.qmltypes
+QMLTYPES_INSTALL_DIR = $$[QT_INSTALL_QML]/QtQuick/Controls/impl
+QML_IMPORT_NAME = QtQuick.Controls.impl
+QML_IMPORT_VERSION = 2.15
+CONFIG += qmltypes install_qmltypes install_metatypes
+
+load(qt_module)