Add valueRole API to ComboBox

This allows the user to conveniently manage data for a role associated with
the text role. A common example of this is an enum stored in a backend with
nicely formatted text displayed to the user. Before this patch, developers
would have to write code like this:

    ComboBox {
        textRole: "text"
        onActivated: backend.modifier = model[currentIndex].value
        Component.onCompleted: currentIndex = findValue(backend.modifier)
        model: [
            { value: Qt.NoModifier, text: qsTr("No modifier") },
            { value: Qt.ShiftModifier, text: qsTr("Shift") },
            { value: Qt.ControlModifier, text: qsTr("Control") }
        ]

        function findValue(value) {
            for (var i = 0; i < model.length; ++i) {
                if (model[i].value === value)
                    return i
            }
            return -1
        }
    }

With this patch, the code becomes much simpler:

    ComboBox {
        textRole: "text"
        valueRole: "value"
        onActivated: backend.modifier = currentValue
        Component.onCompleted: currentIndex = indexOfValue(backend.modifier)
        model: [
            { value: Qt.NoModifier, text: qsTr("No modifier") },
            { value: Qt.ShiftModifier, text: qsTr("Shift") },
            { value: Qt.ControlModifier, text: qsTr("Control") }
        ]
    }

[ChangeLog][Controls][ComboBox] Added valueRole, currentValue and
indexOfValue(). These allow convenient management of data for a role
associated with the text role.

Change-Id: I0ed19bd0ba9cf6b044a8113ff1a8782d43065449
Fixes: QTBUG-73491
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

1 files changed, 65 insertions, 1 deletions

diff --git a/tests/auto/controls/data/tst_combobox.qml b/tests/auto/controls/data/tst_combobox.qml
index 7f061a2b..7d65b698 100644
--- a/tests/auto/controls/data/tst_combobox.qml
+++ b/tests/auto/controls/data/tst_combobox.qml
@@ -351,9 +351,73 @@ TestCase {
         compare(control.find(data.term, data.flags), data.index)
     }
 
+    function test_valueRole_data() {
+        return [
+            { tag: "ListModel", model: fruitmodel },
+            { tag: "ObjectArray", model: fruitarray }
+        ]
+    }
+
+    function test_valueRole(data) {
+        var control = createTemporaryObject(emptyBox, testCase,
+            { model: data.model, valueRole: "color" })
+        verify(control)
+        compare(control.count, 3)
+        compare(control.currentIndex, 0)
+        compare(control.currentValue, "red")
+
+        control.valueRole = "name"
+        compare(control.currentValue, "Apple")
+
+        control.currentIndex = 1
+        compare(control.currentIndex, 1)
+        compare(control.currentValue, "Orange")
+
+        control.valueRole = "color"
+        compare(control.currentValue, "orange")
+
+        control.model = null
+        compare(control.currentIndex, -1)
+        // An invalid QVariant is represented as undefined.
+        compare(control.currentValue, undefined)
+
+        control.valueRole = ""
+        compare(control.currentValue, undefined)
+    }
+
+    function test_valueAt() {
+        var control = createTemporaryObject(comboBox, testCase,
+            { model: fruitmodel, textRole: "name", valueRole: "color" })
+        verify(control)
+
+        compare(control.valueAt(0), "red")
+        compare(control.valueAt(1), "orange")
+        compare(control.valueAt(2), "yellow")
+        compare(control.valueAt(-1), undefined)
+        compare(control.valueAt(5), undefined)
+    }
+
+    function test_indexOfValue_data() {
+        return [
+            { tag: "red", expectedIndex: 0 },
+            { tag: "orange", expectedIndex: 1 },
+            { tag: "yellow", expectedIndex: 2 },
+            { tag: "brown", expectedIndex: -1 },
+        ]
+    }
+
+    function test_indexOfValue(data) {
+        var control = createTemporaryObject(comboBox, testCase,
+            { model: fruitmodel, textRole: "name", valueRole: "color" })
+        verify(control)
+
+        compare(control.indexOfValue(data.tag), data.expectedIndex)
+    }
+
 
     function test_arrowKeys() {
-        var control = createTemporaryObject(comboBox, testCase, {model: 3})
+        var control = createTemporaryObject(comboBox, testCase,
+            { model: fruitmodel, textRole: "name", valueRole: "color" })
         verify(control)
 
         var activatedSpy = signalSpy.createObject(control, {target: control, signalName: "activated"})