Clean up resource handling

Since Qt 5.6 it is possible to pass "objects" to RESOURCES that describe
files and prefix directly. That allows getting rid of the qmake code to
generate .qrc files here, resources.prf does that by itself now.

Change-Id: Ibdcfd47355aeb10b83d23f6b00ec55b179b03bbf
Reviewed-by: Jarkko Koivikko <jarkko.koivikko@code-q.fi>
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

3 files changed, 12 insertions, 35 deletions

diff --git a/src/virtualkeyboard/3rdparty/t9write/t9write.pro b/src/virtualkeyboard/3rdparty/t9write/t9write.pro
index d64f831d..3594a97e 100644
--- a/src/virtualkeyboard/3rdparty/t9write/t9write.pro
+++ b/src/virtualkeyboard/3rdparty/t9write/t9write.pro
@@ -14,9 +14,9 @@ T9WRITE_RESOURCE_FILES = \
 QMAKE_RESOURCE_FLAGS += -no-compress
 CONFIG += resources_big
 
-include(../../generateresource.pri)
-
-RESOURCES += $$generate_resource(t9write_db.qrc, $$T9WRITE_RESOURCE_FILES, /QtQuick/VirtualKeyboard/T9Write)
+t9write_db.files = $$T9WRITE_RESOURCE_FILES
+t9write_db.prefix =/QtQuick/VirtualKeyboard/T9Write
+RESOURCES += t9write_db
 
 load(qt_helper_lib)
 
diff --git a/src/virtualkeyboard/generateresource.pri b/src/virtualkeyboard/generateresource.pri
deleted file mode 100644
index 967d90c5..00000000
--- a/src/virtualkeyboard/generateresource.pri
+++ /dev/null
@@ -1,28 +0,0 @@
-defineReplace(generate_resource) {
-    GENERATED_FILE = $$OUT_PWD/$$1
-    INCLUDED_FILES = $$2
-    BASE_PREFIX = $$3
-    GENERATED_CONTENT = \
-        "<RCC>"
-
-    RESOURCE_PREFIX = ""
-    for (FILE, INCLUDED_FILES) {
-        RELATIVE_PATH = $$relative_path($$absolute_path($$FILE), $$_PRO_FILE_PWD_)
-        TEST_PREFIX = $$BASE_PREFIX/$$dirname(RELATIVE_PATH)
-        !equals(TEST_PREFIX, $$RESOURCE_PREFIX) {
-            !isEmpty(RESOURCE_PREFIX): GENERATED_CONTENT += "    </qresource>"
-            RESOURCE_PREFIX = $$TEST_PREFIX
-            GENERATED_CONTENT += "    <qresource prefix=\"$$RESOURCE_PREFIX\">"
-        }
-        ABSOLUTE_PATH = $$absolute_path($$FILE)
-        ALIAS_NAME = $$basename(FILE)
-        GENERATED_CONTENT += "        <file alias=\"$$ALIAS_NAME\">$$ABSOLUTE_PATH</file>"
-    }
-    !isEmpty(RESOURCE_PREFIX): GENERATED_CONTENT += "    </qresource>"
-
-    GENERATED_CONTENT += \
-        "</RCC>"
-    write_file($$GENERATED_FILE, GENERATED_CONTENT)|error("Failed to write resource file!")
-
-    return($$GENERATED_FILE)
-}
diff --git a/src/virtualkeyboard/virtualkeyboard.pro b/src/virtualkeyboard/virtualkeyboard.pro
index 0fd9c933..4990c44c 100644
--- a/src/virtualkeyboard/virtualkeyboard.pro
+++ b/src/virtualkeyboard/virtualkeyboard.pro
@@ -16,7 +16,6 @@ win32 {
 !no-pkg-config: CONFIG += link_pkgconfig
 
 include(../config.pri)
-include(generateresource.pri)
 
 SOURCES += platforminputcontext.cpp \
     inputcontext.cpp \
@@ -353,7 +352,9 @@ pinyin {
     QMAKE_USE += pinyin
     !no-bundle-pinyin {
         PINYIN_FILES += 3rdparty/pinyin/data/dict_pinyin.dat
-        RESOURCES += $$generate_resource(pinyin.qrc, $$PINYIN_FILES, /QtQuick/VirtualKeyboard)
+        pinyin.files = $$PINYIN_FILES
+        pinyin.prefix = /QtQuick/VirtualKeyboard
+        RESOURCES += pinyin
     } else {
         pinyin_data.files = $$PWD/3rdparty/pinyin/data/dict_pinyin.dat
         pinyin_data.path = $$DATAPATH/pinyin
@@ -377,7 +378,9 @@ tcime {
             3rdparty/tcime/data/qt/dict_cangjie.dat
         zhuyin: TCIME_FILES += \
             3rdparty/tcime/data/qt/dict_zhuyin.dat
-        RESOURCES += $$generate_resource(tcime.qrc, $$TCIME_FILES, /QtQuick/VirtualKeyboard)
+        tcime.files = $$TCIME_FILES
+        tcime.prefix = /QtQuick/VirtualKeyboard
+        RESOURCES += tcime
     } else {
         tcime_data.files = \
             $$PWD/3rdparty/tcime/data/qt/dict_phrases.dat
@@ -487,7 +490,9 @@ record-trace-input {
 arrow-key-navigation: DEFINES += QT_VIRTUALKEYBOARD_ARROW_KEY_NAVIGATION
 
 !disable-layouts {
-    RESOURCES += $$generate_resource(layouts.qrc, $$LAYOUT_FILES, /QtQuick/VirtualKeyboard)
+    layouts.files = $$LAYOUT_FILES
+    layouts.prefix = /QtQuick/VirtualKeyboard
+    RESOURCES += layouts
     DEFINES += HAVE_LAYOUTS
 }