use qt_helper_lib.prf for helper libraries

this ensures naming and installation uniformity.

hunspell is now built statically, for the same reason.

Change-Id: I722f16bda4671a71419920f3ab3bedf03df92f0e
Reviewed-by: Joerg Bornemann <joerg.bornemann@theqtcompany.com>

6 files changed, 45 insertions, 95 deletions

diff --git a/src/virtualkeyboard/3rdparty/hunspell/hunspell.pro b/src/virtualkeyboard/3rdparty/hunspell/hunspell.pro
index ce5a90f6..93bdb2c4 100644
--- a/src/virtualkeyboard/3rdparty/hunspell/hunspell.pro
+++ b/src/virtualkeyboard/3rdparty/hunspell/hunspell.pro
@@ -1,35 +1,12 @@
-TEMPLATE = lib
-QT -= core gui
+TARGET = qthunspell
+
 DEFINES += BUILDING_LIBHUNSPELL
-CONFIG += dll
-#CONFIG += staticlib
+CONFIG += static
 CONFIG += precompile_header warn_off
-debug {
+CONFIG(debug, debug|release) {
     DEFINES += HUNSPELL_WARNING_ON
 }
 
-build_pass {
-    CONFIG(debug, debug|release) {
-        SUBPATH = debug
-        win32: TARGET_SUFFIX = d
-    } else {
-        SUBPATH = release
-    }
-} else {
-    debug_and_release: CONFIG += build_all
-    else:win32:CONFIG(debug, debug|release): TARGET_SUFFIX = d
-}
-
-DESTDIR = $$SUBPATH
-
-TARGET = hunspell$$TARGET_SUFFIX
-
-dll {
-    win32: CONFIG += skip_target_version_ext
-    target.path = $$[QT_INSTALL_LIBS]
-    INSTALLS += target
-}
-
 config_file = "/* Version number of package */" "$${LITERAL_HASH}define VERSION \"$$VERSION\""
 write_file($$PWD/config.h, config_file)
 
@@ -75,3 +52,5 @@ OTHER_FILES +=\
     src/hunspell/license.hunspell \
     src/hunspell/license.myspell \
     src/hunspell/utf_info.cxx
+
+load(qt_helper_lib)
diff --git a/src/virtualkeyboard/3rdparty/openwnn/openwnn.pro b/src/virtualkeyboard/3rdparty/openwnn/openwnn.pro
index 0068df18..6ca93d36 100644
--- a/src/virtualkeyboard/3rdparty/openwnn/openwnn.pro
+++ b/src/virtualkeyboard/3rdparty/openwnn/openwnn.pro
@@ -1,20 +1,9 @@
-TEMPLATE = lib
-QT += core-private
-QT -= gui
-TARGET = openwnn
+TARGET = qtopenwnn
+
 VERSION = 1.3.6
-CONFIG += staticlib
+CONFIG += static
 CONFIG += warn_off
 
-build_pass {
-    CONFIG(debug, debug|release): SUBPATH = debug
-    else: SUBPATH = release
-} else {
-    debug_and_release: CONFIG += build_all
-}
-
-DESTDIR = $$SUBPATH
-
 INCLUDEPATH += \
     wnnDictionary/include \
     wnnEngine/include
@@ -59,3 +48,8 @@ HEADERS += \
     wnnEngine/include/romkan.h \
     wnnEngine/include/romkanfullkatakana.h \
     wnnEngine/include/romkanhalfkatakana.h
+
+load(qt_helper_lib)
+
+CONFIG += qt
+QT = core-private
diff --git a/src/virtualkeyboard/3rdparty/pinyin/pinyin.pro b/src/virtualkeyboard/3rdparty/pinyin/pinyin.pro
index 9668f668..8aab0eef 100644
--- a/src/virtualkeyboard/3rdparty/pinyin/pinyin.pro
+++ b/src/virtualkeyboard/3rdparty/pinyin/pinyin.pro
@@ -1,20 +1,9 @@
-TEMPLATE = lib
-win32: QT -= gui
-else: CONFIG -= qt
-TARGET = pinyin
+TARGET = qtpinyin
+
 VERSION = 1.0.0
-CONFIG += staticlib
+CONFIG += static
 CONFIG += warn_off
 
-build_pass {
-    CONFIG(debug, debug|release): SUBPATH = debug
-    else: SUBPATH = release
-} else {
-    debug_and_release: CONFIG += build_all
-}
-
-DESTDIR = $$SUBPATH
-
 INCLUDEPATH += \
     include
 
@@ -59,3 +48,11 @@ HEADERS += \
 OTHER_FILES +=\
     data/rawdict_utf16_65105_freq.txt \
     data/valid_utf16.txt
+
+load(qt_helper_lib)
+
+# On Windows, the library uses Qt for platform abstraction.
+win32 {
+    CONFIG += qt
+    QT = core
+}
diff --git a/src/virtualkeyboard/3rdparty/t9write/t9write.pro b/src/virtualkeyboard/3rdparty/t9write/t9write.pro
index 197d1015..40461ba0 100644
--- a/src/virtualkeyboard/3rdparty/t9write/t9write.pro
+++ b/src/virtualkeyboard/3rdparty/t9write/t9write.pro
@@ -1,15 +1,6 @@
-TEMPLATE = lib
-CONFIG += staticlib
-TARGET = t9write_db
+TARGET = qtt9write_db
 
-build_pass {
-    CONFIG(debug, debug|release): SUBPATH = debug
-    else: SUBPATH = release
-} else {
-    debug_and_release: CONFIG += build_all
-}
-
-DESTDIR = $$SUBPATH
+CONFIG += static
 
 T9WRITE_LDBS = $$files(databases/XT9_LDBs/*.ldb)
 
@@ -23,3 +14,5 @@ QMAKE_RESOURCE_FLAGS += -no-compress
 include(../../generateresource.pri)
 
 RESOURCES += $$generate_resource(t9write_db.qrc, $$T9WRITE_RESOURCE_FILES)
+
+load(qt_helper_lib)
diff --git a/src/virtualkeyboard/3rdparty/tcime/tcime.pro b/src/virtualkeyboard/3rdparty/tcime/tcime.pro
index 218563a6..86755635 100644
--- a/src/virtualkeyboard/3rdparty/tcime/tcime.pro
+++ b/src/virtualkeyboard/3rdparty/tcime/tcime.pro
@@ -1,16 +1,6 @@
-TEMPLATE = lib
-QT -= gui
-TARGET = tcime
-CONFIG += staticlib
+TARGET = qttcime
 
-build_pass {
-    CONFIG(debug, debug|release): SUBPATH = debug
-    else: SUBPATH = release
-} else {
-    debug_and_release: CONFIG += build_all
-}
-
-DESTDIR = $$SUBPATH
+CONFIG += static
 
 SOURCES += \
     cangjiedictionary.cpp \
@@ -31,3 +21,8 @@ HEADERS += \
 OTHER_FILES += \
     data/dict_cangjie.dat \
     data/dict_phrases.dat
+
+load(qt_helper_lib)
+
+CONFIG += qt
+QT = core
diff --git a/src/virtualkeyboard/virtualkeyboard.pro b/src/virtualkeyboard/virtualkeyboard.pro
index 7a437ff2..dff9db8a 100644
--- a/src/virtualkeyboard/virtualkeyboard.pro
+++ b/src/virtualkeyboard/virtualkeyboard.pro
@@ -214,17 +214,6 @@ HEADERS += appinputpanel.h
 
 qtquickcompiler: DEFINES += COMPILING_QML
 
-build_pass {
-    CONFIG(debug, debug|release) {
-        SUBPATH = debug
-        win32: TARGET_SUFFIX = d
-    } else {
-        SUBPATH = release
-    }
-} else {
-    !debug_and_release:win32:CONFIG(debug, debug|release): TARGET_SUFFIX = d
-}
-
 static {
     LIBS += \
         -L$$[QT_INSTALL_QML]/QtQuick.2 -lqtquick2plugin$$TARGET_SUFFIX \
@@ -240,7 +229,7 @@ static {
         HEADERS += hunspellinputmethod.h hunspellinputmethod_p.h hunspellworker.h
         DEFINES += HAVE_HUNSPELL
         INCLUDEPATH += 3rdparty/hunspell/src
-        LIBS += -L$$OUT_PWD/3rdparty/hunspell/$$SUBPATH -lhunspell$$TARGET_SUFFIX
+        LIBS += -L$$OUT_PWD/../../lib -lqthunspell$$qtPlatformTargetSuffix()
         exists(3rdparty/hunspell/data) {
             hunspell_data.files = 3rdparty/hunspell/data/*.dic 3rdparty/hunspell/data/*.aff
             hunspell_data.path = $$DATAPATH/hunspell
@@ -268,7 +257,7 @@ pinyin {
         pinyindecoderservice.h
     DEFINES += HAVE_PINYIN
     INCLUDEPATH += 3rdparty/pinyin/include
-    LIBS += -L$$OUT_PWD/3rdparty/pinyin/$$SUBPATH -lpinyin
+    LIBS += -L$$OUT_PWD/../../lib -lqtpinyin$$qtPlatformTargetSuffix()
     pinyin_data.files = $$PWD/3rdparty/pinyin/data/dict_pinyin.dat
     pinyin_data.path = $$DATAPATH/pinyin
     INSTALLS += pinyin_data
@@ -283,7 +272,7 @@ tcime {
     cangjie: DEFINES += HAVE_TCIME_CANGJIE
     zhuyin: DEFINES += HAVE_TCIME_ZHUYIN
     INCLUDEPATH += 3rdparty/tcime
-    LIBS += -L$$OUT_PWD/3rdparty/tcime/$$SUBPATH -ltcime
+    LIBS += -L$$OUT_PWD/../../lib -lqttcime$$qtPlatformTargetSuffix()
     tcime_data.files = \
         $$PWD/3rdparty/tcime/data/qt/dict_phrases.dat
     cangjie: tcime_data.files += \
@@ -310,7 +299,7 @@ openwnn {
     DEFINES += HAVE_OPENWNN
     INCLUDEPATH += 3rdparty/openwnn/wnnEngine/include
     # OpenWNN engine
-    LIBS += -L$$OUT_PWD/3rdparty/openwnn/$$SUBPATH -lopenwnn
+    LIBS += -L$$OUT_PWD/../../lib -lqtopenwnn$$qtPlatformTargetSuffix()
 }
 
 lipi-toolkit:t9write: \
@@ -331,7 +320,10 @@ lipi-toolkit {
     INCLUDEPATH += \
         3rdparty/lipi-toolkit/src/include \
         3rdparty/lipi-toolkit/src/util/lib
-    LIBS += -L$$OUT_PWD/3rdparty/lipi-toolkit/src/lib/$$SUBPATH -lshaperecommon -lltkcommon -lltkutil
+    LIBS += -L$$OUT_PWD/../../lib \
+        -lqtshaperecommon$$qtPlatformTargetSuffix() \
+        -lqtltkcommon$$qtPlatformTargetSuffix() \
+        -lqtltkutil$$qtPlatformTargetSuffix()
     win32: LIBS += Advapi32.lib
     else: LIBS += -ldl
     record-trace-input: DEFINES += QT_VIRTUALKEYBOARD_LIPI_RECORD_TRACE_INPUT
@@ -350,7 +342,7 @@ t9write {
         t9writeworker.h
     DEFINES += HAVE_T9WRITE
     INCLUDEPATH += $$T9WRITE_INCLUDE_DIRS
-    LIBS += -L$$OUT_PWD/3rdparty/t9write/$$SUBPATH -lt9write_db
+    LIBS += -L$$OUT_PWD/../../lib -lqtt9write_db$$qtPlatformTargetSuffix()
     LIBS += $$T9WRITE_ALPHABETIC_LIBS
 }