blob: 81f6d21d4816fbee52a673f5017d153789244b48 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
|
# Copyright (C) 2022 The Qt Company Ltd.
# SPDX-License-Identifier: BSD-3-Clause
#[=======================================================================[.rst:
FindMyScript
------------
Searches for MyScript SDK.
Imported Targets
^^^^^^^^^^^^^^^^
This module provides the following imported targets, if found:
``MyScript::VOIM``
The MyScript VOIM library
Result Variables
^^^^^^^^^^^^^^^^
``MyScript_FOUND``
TRUE if MyScript SDK is found.
Cache Variables
^^^^^^^^^^^^^^^
``MyScript_ROOT_DIR``
It is a required variable and it indicates the location of the MyScript SDK.
Please contact MyScript Support team to get detailed installation guide.
``MyScript_BINARIES``
It is a list of MyScript Library Binaries which need to be installed.
It includes required variables: MyScript_VOIM_BINARY, MyScript_Ink_BINARY,
MyScript_Prediction_BINARY, MyScript_Text_BINARY and MyScript_Engine_BINARY.
#]=======================================================================]
set(MYSCRIPT_REQUIRED_VARS
MyScript_ROOT_DIR
MyScript_VOIM_INCLUDE_DIR
MyScript_VOIM_BINARY
MyScript_Ink_BINARY
MyScript_Prediction_BINARY
MyScript_Text_BINARY
MyScript_Engine_BINARY
)
if(NOT MyScript_ROOT_DIR)
if(INPUT_vkb_myscript_sdk)
set(MyScript_ROOT_DIR ${INPUT_vkb_myscript_sdk} CACHE STRING "" FORCE)
elseif(DEFINED ENV{MYSCRIPT_SDK_ROOT})
set(MyScript_ROOT_DIR $ENV{MYSCRIPT_SDK_ROOT} CACHE STRING "" FORCE)
elseif(EXISTS "${QtVirtualKeyboard_SOURCE_DIR}/src/plugins/myscript/sdk")
set(MyScript_ROOT_DIR "${QtVirtualKeyboard_SOURCE_DIR}/src/plugins/myscript/sdk" CACHE STRING "" FORCE)
endif()
endif()
if(MyScript_ROOT_DIR AND NOT MyScript_ARCH)
if(INPUT_vkb_myscript_arch)
if(WIN32)
set(MyScript_ARCH "win-${INPUT_vkb_myscript_arch}")
else()
set(MyScript_ARCH "lin-${INPUT_vkb_myscript_arch}")
endif()
else()
if(WIN32)
if(CMAKE_SIZEOF_VOID_P MATCHES "8")
set(MyScript_ARCH "win-x64")
else()
set(MyScript_ARCH "win-x86")
endif()
else()
if (CMAKE_SYSTEM_PROCESSOR MATCHES "arm64")
set(MyScript_ARCH "lin-arm64")
elseif (CMAKE_SYSTEM_PROCESSOR MATCHES "arm")
set(MyScript_ARCH "lin-armv7hf")
elseif (CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64")
set(MyScript_ARCH "lin-x64")
elseif (CMAKE_SYSTEM_PROCESSOR MATCHES "i386" OR CMAKE_SYSTEM_PROCESSOR MATCHES "x86")
set(MyScript_ARCH "lin-x86")
endif()
endif()
endif()
endif()
find_path(MyScript_VOIM_INCLUDE_DIR
NAMES "voim.h"
PATHS "${MyScript_ROOT_DIR}/voim/api/c/include"
NO_DEFAULT_PATH
)
if(NOT MyScript_VOIM_INCLUDE_DIR STREQUAL "MyScript_VOIM_INCLUDE_DIR-NOTFOUND")
if(WIN32)
find_file(MyScript_VOIM_BINARY
NAMES "voim.dll"
PATHS "${MyScript_ROOT_DIR}/voim/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_file(MyScript_Ink_BINARY
NAMES "MyScriptInk.dll"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_file(MyScript_Prediction_BINARY
NAMES "MyScriptPrediction.dll"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_file(MyScript_Text_BINARY
NAMES "MyScriptText.dll"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_file(MyScript_Engine_BINARY
NAMES "MyScriptEngine.dll"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
else()
find_library(MyScript_VOIM_BINARY
NAMES "voim"
PATHS "${MyScript_ROOT_DIR}/voim/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_library(MyScript_Ink_BINARY
NAMES "MyScriptInk"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_library(MyScript_Prediction_BINARY
NAMES "MyScriptPrediction"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_library(MyScript_Text_BINARY
NAMES "MyScriptText"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
find_library(MyScript_Engine_BINARY
NAMES "MyScriptEngine"
PATHS "${MyScript_ROOT_DIR}/engine/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
endif()
set(MyScript_BINARIES
${MyScript_VOIM_BINARY}
${MyScript_Ink_BINARY}
${MyScript_Prediction_BINARY}
${MyScript_Text_BINARY}
${MyScript_Engine_BINARY}
CACHE STRING "" FORCE
)
endif()
if(NOT MyScript_VOIM_BINARY STREQUAL "MyScript_VOIM_BINARY-NOTFOUND" AND NOT TARGET MyScript::VOIM)
add_library(MyScript::VOIM SHARED IMPORTED)
if(WIN32)
find_library(MyScript_VOIM_LIBRARY
NAMES "voim"
PATHS "${MyScript_ROOT_DIR}/voim/bin/${MyScript_ARCH}"
NO_DEFAULT_PATH
)
list(APPEND MYSCRIPT_REQUIRED_VARS MyScript_VOIM_LIBRARY)
set_target_properties(MyScript::VOIM PROPERTIES
IMPORTED_LOCATION "${MyScript_VOIM_BINARY}"
IMPORTED_IMPLIB "${MyScript_VOIM_LIBRARY}"
INTERFACE_INCLUDE_DIRECTORIES "${MyScript_VOIM_INCLUDE_DIR}"
)
else()
set_target_properties(MyScript::VOIM PROPERTIES
IMPORTED_LOCATION "${MyScript_VOIM_BINARY}"
INTERFACE_INCLUDE_DIRECTORIES "${MyScript_VOIM_INCLUDE_DIR}"
)
endif()
endif()
#
# Common
#
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(MyScript
REQUIRED_VARS ${MYSCRIPT_REQUIRED_VARS}
)
|
