blob: ec34a471e98cf95ce0e9cf4eba7c8c1782b58958 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
// Copyright (C) 2016 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only
import QtQuick
// Deliberately imported after QtQuick to avoid missing restoreMode property in Binding. Fix in Qt 6.
import QtQml
import QtQuick.Window
import QtQuick.VirtualKeyboard
import QtQuick.VirtualKeyboard.Settings
import "content"
Item {
width: 1280
height: 720
Item {
id: appContainer
width: inLandscapeOrientation ? parent.width : parent.height
height: inLandscapeOrientation ? parent.height : parent.width
anchors.centerIn: parent
Basic {
id: virtualKeyboard
anchors.left: parent.left
anchors.top: parent.top
anchors.right: parent.right
anchors.bottom: inputPanel.top
handwritingInputPanelActive: handwritingInputPanel.available && handwritingInputPanel.active
}
/* Handwriting input panel for full screen handwriting input.
This component is an optional add-on for the InputPanel component, that
is, its use does not affect the operation of the InputPanel component,
but it also can not be used as a standalone component.
The handwriting input panel is positioned to cover the entire area of
application. The panel itself is transparent, but once it is active the
user can draw handwriting on it.
*/
HandwritingInputPanel {
z: 79
id: handwritingInputPanel
anchors.fill: parent
inputPanel: inputPanel
Rectangle {
z: -1
anchors.fill: parent
color: "black"
opacity: 0.10
}
}
/* Container area for the handwriting mode button.
Handwriting mode button can be moved freely within the container area.
In this example, a single click changes the handwriting mode and a
double-click changes the availability of the full screen handwriting input.
*/
Item {
z: 99
visible: handwritingInputPanel.enabled && Qt.inputMethod.visible
anchors { left: parent.left; top: parent.top; right: parent.right; bottom: inputPanel.top; }
HandwritingModeButton {
id: handwritingModeButton
anchors.top: parent.top
anchors.right: parent.right
anchors.margins: 10
floating: true
flipable: true
width: 76
height: width
state: handwritingInputPanel.state
onClicked: handwritingInputPanel.active = !handwritingInputPanel.active
onDoubleClicked: handwritingInputPanel.available = !handwritingInputPanel.available
}
}
/* Keyboard input panel.
The keyboard is anchored to the bottom of the application.
*/
InputPanel {
id: inputPanel
z: 89
y: yPositionWhenHidden
x: 0
width: parent.width
property real yPositionWhenHidden: parent.height
states: State {
name: "visible"
/* The visibility of the InputPanel can be bound to the Qt.inputMethod.visible property,
but then the handwriting input panel and the keyboard input panel can be visible
at the same time. Here the visibility is bound to InputPanel.active property instead,
which allows the handwriting panel to control the visibility when necessary.
*/
when: inputPanel.active
PropertyChanges {
target: inputPanel
y: inputPanel.yPositionWhenHidden - inputPanel.height
}
}
transitions: Transition {
id: inputPanelTransition
from: ""
to: "visible"
reversible: true
enabled: !VirtualKeyboardSettings.fullScreenMode
ParallelAnimation {
NumberAnimation {
properties: "y"
duration: 250
easing.type: Easing.InOutQuad
}
}
}
Binding {
target: InputContext
property: "animating"
value: inputPanelTransition.running
restoreMode: Binding.RestoreBinding
}
AutoScroller {}
}
Binding {
target: VirtualKeyboardSettings
property: "fullScreenMode"
value: appContainer.height > 0 && (appContainer.width / appContainer.height) > (16.0 / 9.0)
restoreMode: Binding.RestoreBinding
}
}
property bool inLandscapeOrientation: Screen.primaryOrientation === Qt.LandscapeOrientation ||
Screen.primaryOrientation === Qt.InvertedLandscapeOrientation
Binding {
target: appContainer.Window.window !== null ? appContainer.Window.window.contentItem : null
property: "rotation"
value: inLandscapeOrientation ? 0 : 90
}
}
|
