blob: 99eab6c9413f623d19ebf4dc9e09055df51e1e9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
TARGET = qtvirtualkeyboard_hunspell
QT += qml virtualkeyboard hunspellinputmethod-private
HEADERS += \
hunspellplugin.h
SOURCES += \
hunspellplugin.cpp
OTHER_FILES += \
hunspell.json
include(../../../config.pri)
hunspell-library {
exists(../3rdparty/hunspell/data) {
hunspell_data.files = \
$$PWD/../3rdparty/hunspell/data/*.dic \
$$PWD/../3rdparty/hunspell/data/*.aff
hunspell_data.path = $$VIRTUALKEYBOARD_INSTALL_DATA/hunspell
INSTALLS += hunspell_data
!prefix_build: COPIES += hunspell_data
} else {
error("Hunspell dictionaries are missing! Please copy .dic and .aff" \
"files to src/plugins/hunspell/3rdparty/hunspell/data directory.")
}
}
win32 {
QMAKE_TARGET_PRODUCT = "Qt Virtual Keyboard Hunspell (Qt $$QT_VERSION)"
QMAKE_TARGET_DESCRIPTION = "Virtual Keyboard Extension for Qt."
}
PLUGIN_TYPE = virtualkeyboard
PLUGIN_CLASS_NAME = QtVirtualKeyboardHunspellPlugin
load(qt_plugin)
|