blob: c11eb09a7091d03c8b90fb29c020083ca0db5d82 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
TARGET = qtvirtualkeyboard_tcime
QT += qml virtualkeyboard-private
include(../../../shared.pri)
HEADERS += \
tcinputmethod_p.h \
tcimeplugin.h
SOURCES += \
tcinputmethod.cpp \
tcimeplugin.cpp
OTHER_FILES += \
tcime.json
DEFINES += \
QT_NO_CAST_TO_ASCII \
QT_ASCII_CAST_WARNINGS \
QT_NO_CAST_FROM_ASCII \
QT_NO_CAST_FROM_BYTEARRAY
LAYOUT_FILES += \
$$LAYOUTS_BASE/content/layouts/zh_TW/dialpad.fallback \
$$LAYOUTS_BASE/content/layouts/zh_TW/digits.fallback \
$$LAYOUTS_BASE/content/layouts/zh_TW/main.qml \
$$LAYOUTS_BASE/content/layouts/zh_TW/numbers.fallback \
$$LAYOUTS_BASE/content/layouts/zh_TW/symbols.qml
virtualkeyboard_tcime_layouts.files = $$LAYOUT_FILES
virtualkeyboard_tcime_layouts.base = $$LAYOUTS_BASE
virtualkeyboard_tcime_layouts.prefix = $$LAYOUTS_PREFIX
RESOURCES += virtualkeyboard_tcime_layouts
QMAKE_USE += tcime
!no-bundle-tcime {
TCIME_FILES += ../3rdparty/tcime/data/qt/dict_phrases.dat
qtConfig(cangjie): TCIME_FILES += \
../3rdparty/tcime/data/qt/dict_cangjie.dat
qtConfig(zhuyin): TCIME_FILES += \
../3rdparty/tcime/data/qt/dict_zhuyin.dat
tcime.files = $$TCIME_FILES
tcime.base = $$PWD/..
tcime.prefix = /QtQuick/VirtualKeyboard
RESOURCES += tcime
} else {
tcime_data.files = \
$$PWD/../3rdparty/tcime/data/qt/dict_phrases.dat
qtConfig(cangjie): tcime_data.files += \
$$PWD/../3rdparty/tcime/data/qt/dict_cangjie.dat
qtConfig(zhuyin): tcime_data.files += \
$$PWD/../3rdparty/tcime/data/qt/dict_zhuyin.dat
tcime_data.path = $$VIRTUALKEYBOARD_INSTALL_DATA/tcime
INSTALLS += tcime_data
!prefix_build: COPIES += tcime_data
}
win32 {
QMAKE_TARGET_PRODUCT = "Qt Virtual Keyboard TCIME (Qt $$QT_VERSION)"
QMAKE_TARGET_DESCRIPTION = "Virtual Keyboard Extension for Qt."
}
PLUGIN_TYPE = virtualkeyboard
PLUGIN_CLASS_NAME = QtVirtualKeyboardTCImePlugin
load(qt_plugin)
|
