Merge branch 'wip-compositor-api' into dev

This introduces the new compositor API, removing the
old API (which was never officially supported).

Change-Id: I1dc01f0fb4edc749e34ed8356e56ad87d7d64913

1 files changed, 45 insertions, 0 deletions

diff --git a/src/imports/compositor/compositor.pro b/src/imports/compositor/compositor.pro
new file mode 100644
index 000000000..a97f90f48
--- /dev/null
+++ b/src/imports/compositor/compositor.pro
@@ -0,0 +1,45 @@
+CXX_MODULE = qml
+TARGET  = qwaylandcompositorplugin
+TARGETPATH = QtWayland/Compositor
+IMPORT_VERSION = 1.0
+
+HEADERS += \
+    qwaylandmousetracker_p.h
+
+SOURCES += \
+    qwaylandquickcompositorplugin.cpp \
+    qwaylandmousetracker.cpp
+
+COMPOSITOR_QML_FILES += \
+    WaylandOutputWindow.qml \
+    WaylandCursorItem.qml \
+    qmldir
+
+# Create the resource file
+GENERATED_RESOURCE_FILE = $$OUT_PWD/compositor.qrc
+
+RESOURCE_CONTENT = \
+    "<RCC>" \
+    "<qresource prefix=\"/QtWayland/Compositor\">"
+
+for(resourcefile, COMPOSITOR_QML_FILES) {
+    resourcefileabsolutepath = $$absolute_path($$resourcefile)
+    relativepath_in = $$relative_path($$resourcefileabsolutepath, $$_PRO_FILE_PWD_)
+    relativepath_out = $$relative_path($$resourcefileabsolutepath, $$OUT_PWD)
+    RESOURCE_CONTENT += "<file alias=\"$$relativepath_in\">$$relativepath_out</file>"
+}
+
+RESOURCE_CONTENT += \
+    "</qresource>" \
+    "</RCC>"
+
+write_file($$GENERATED_RESOURCE_FILE, RESOURCE_CONTENT)|error("Aborting.")
+
+RESOURCES += $$GENERATED_RESOURCE_FILE
+
+# In case of a debug build, deploy the QML files too
+CONFIG(debug, debug|release): QML_FILES += $$COMPOSITOR_QML_FILES
+
+QT += quick-private qml-private gui-private core-private waylandcompositor waylandcompositor-private
+
+load(qml_plugin)