1 files changed, 98 insertions, 0 deletions
diff --git a/src/client/client.pro b/src/client/client.pro
new file mode 100644
index 000000000..01d704a94
--- /dev/null
+++ b/src/client/client.pro
@@ -0,0 +1,98 @@
+TARGET = QtWaylandClient
+QT += core-private gui-private
+QT_FOR_PRIVATE += platformsupport-private
+
+MODULE=waylandclient
+load(qt_module)
+
+CONFIG += link_pkgconfig qpa/genericunixfontdatabase wayland-scanner
+
+!equals(QT_WAYLAND_GL_CONFIG, nogl) {
+    DEFINES += QT_WAYLAND_GL_SUPPORT
+}
+
+config_xkbcommon {
+    !contains(QT_CONFIG, no-pkg-config) {
+        PKGCONFIG += xkbcommon
+    } else {
+        LIBS += -lxkbcommon
+    }
+} else {
+    DEFINES += QT_NO_WAYLAND_XKB
+}
+
+!contains(QT_CONFIG, no-pkg-config) {
+    PKGCONFIG += wayland-client wayland-cursor
+    contains(QT_CONFIG, glib): PKGCONFIG_PRIVATE += glib-2.0
+} else {
+    LIBS += -lwayland-client -lwayland-cursor $$QT_LIBS_GLIB
+}
+
+INCLUDEPATH += $$PWD/../shared
+
+WAYLANDCLIENTSOURCES += \
+            ../3rdparty/protocol/wayland.xml \
+            ../extensions/surface-extension.xml \
+            ../extensions/sub-surface-extension.xml \
+            ../extensions/output-extension.xml \
+            ../extensions/touch-extension.xml \
+            ../extensions/qtkey-extension.xml \
+            ../extensions/windowmanager.xml \
+            ../3rdparty/protocol/text.xml \
+
+SOURCES +=  qwaylandintegration.cpp \
+            qwaylandnativeinterface.cpp \
+            qwaylandshmbackingstore.cpp \
+            qwaylandinputdevice.cpp \
+            qwaylandcursor.cpp \
+            qwaylanddisplay.cpp \
+            qwaylandwindow.cpp \
+            qwaylandscreen.cpp \
+            qwaylandshmwindow.cpp \
+            qwaylandclipboard.cpp \
+            qwaylanddnd.cpp \
+            qwaylanddataoffer.cpp \
+            qwaylanddatadevicemanager.cpp \
+            qwaylanddatasource.cpp \
+            qwaylandshellsurface.cpp \
+            qwaylandextendedoutput.cpp \
+            qwaylandextendedsurface.cpp \
+            qwaylandsubsurface.cpp \
+            qwaylandtouch.cpp \
+            qwaylandqtkey.cpp \
+            ../shared/qwaylandmimehelper.cpp \
+            qwaylanddecoration.cpp \
+            qwaylandeventthread.cpp\
+            qwaylandwindowmanagerintegration.cpp \
+            qwaylandinputcontext.cpp \
+            qwaylanddatadevice.cpp \
+
+HEADERS +=  qwaylandintegration_p.h \
+            qwaylandnativeinterface_p.h \
+            qwaylandcursor_p.h \
+            qwaylanddisplay_p.h \
+            qwaylandwindow_p.h \
+            qwaylandscreen_p.h \
+            qwaylandshmbackingstore_p.h \
+            qwaylandinputdevice_p.h \
+            qwaylandbuffer_p.h \
+            qwaylandshmwindow_p.h \
+            qwaylandclipboard_p.h \
+            qwaylanddnd_p.h \
+            qwaylanddataoffer_p.h \
+            qwaylanddatadevicemanager_p.h \
+            qwaylanddatasource_p.h \
+            qwaylandshellsurface_p.h \
+            qwaylandextendedoutput_p.h \
+            qwaylandextendedsurface_p.h \
+            qwaylandsubsurface_p.h \
+            qwaylandtouch_p.h \
+            qwaylandqtkey_p.h \
+            ../shared/qwaylandmimehelper.h \
+            qwaylanddecoration_p.h \
+            qwaylandeventthread_p.h \
+            qwaylandwindowmanagerintegration_p.h \
+            qwaylandinputcontext_p.h \
+            qwaylanddatadevice_p.h \
+
+include(hardwareintegration/hardwareintegration.pri)